集成测试期间约束上的 Grails null id 错误

Question

Grails 2.2.0

我正在尝试创建一个自定义约束来强制用户只有一个主电子邮件。这是导致错误的简化代码：

用户域类

class User {

    static hasMany = [emails: Email]

    static constraints = {
    }
}

电子邮件域类

class Email {

    static belongsTo = [user: User]
    String emailAddress
    Boolean isMaster

    static constraints = {

        emailAddress unique: ['user']
        isMaster validator: { val, obj ->
            return !val || Email.findByUserAndIsMaster(obj.user, true) == null
        }

    }
}

集成测试

class EmailTests {

    @Before
    void setUp() {

    }

    @After
    void tearDown() {
        // Tear down logic here
    }

    @Test
    void testSomething() {
        def john = (new User(login: 'johnDoe')).save(failOnError: true, flush: true)
        assert (new Email(emailAddress: 'john@gmail.com', user: john, isMaster: true)).save(failOnError: true)
    }
}

运行“grails test-app -integration”会导致：

|失败：testSomething(webapp.EmailTests)
| org.hibernate.AssertionFailure：webapp.Email 条目中的空 id（发生异常后不要刷新会话） 在 org.grails.datastore.gorm.GormStaticApi$_methodMissing_closure2.doCall(GormStaticApi.groovy:105) 在 webapp.Email$__clinit__closure1_closure2.doCall(Email.groovy:13) 在 org.grails.datastore.mapping.engine.event.AbstractPersistenceEventListener.onApplicationEvent(AbstractPersistenceEventListener.java:46) 在 webapp.EmailTests.testSomething(EmailTests.groovy:21)

如果我将唯一约束更改为自定义约束之后，问题将不会发生。这里发生了什么？我想了解这里的任何相关约束的顺序如何？

要明确，这不会导致问题：

static constraints = {
        isMaster validator: { val, obj ->
            return !val || Email.findByUserAndIsMaster(obj.user, true) == null
        }
        emailAddress unique: ['user']
    }

Answer 1

我想我明白了……一对多的关系被打破了。

让我解释一下

• 测试中的第一行创建了User john，该User john 被保存并刷新。
• 第二行创建一个Email 并将john 设置为用户属性。

一旦你尝试保存Email 实例，GORM 就会报错。那是因为您将 john 分配给 Email，这是关系的反面。拥有方并没有意识到这一点，并且在这一点上什么也没有。简单的说。 在添加到用户之前，您无法保存实例并通过电子邮件发送实例。

这是一个应该有效的测试方法。

void testSomething() {
   def john = new User(login: 'johnDoe')

   john.addToEmails(new Email(emailAddress: 'john@gmail.com', isMaster: true))
   john.save(flush:true)

   assert false == john.errors.hasErrors()
   assert 1 == john.emails.size()  
}

addToEmails() 方法将电子邮件实例添加到集合中，并将用户设置为关系的反面。现在关系已经满足，保存 john 也应该保存所有电子邮件。

---

另一条路线

由于问题似乎是在 Email 验证器中对用户实例的引用，我认为也许您可以采取另一条路线。

class User {
    static hasOne = [master: Email]
    static hasMany = [emails: Email]
}

这将消除对有问题的验证器的需求，这使您的 Email 类依赖于 User 进行验证。您可以让用户对他拥有哪些电子邮件地址以及应该应用哪些规则负责。 您可以将验证器添加到 User 以验证您是否拥有电子邮件列表中不存在的主地址，并验证分配的所有地址是否都是唯一的。 比如：

static constraints = {
    master validator: { master, user, errors ->
        if (master.emailAddress in user.emails*.emailAddress) {
            errors.rejectValue('master', 'error.master', 'Master already in e-mails')
            return false
        }
    }

    emails validator: { emails, user, errors ->
        def addresses = emails*.emailAddress
        if (!addresses.equals(emails*.emailAddress.unique())) {
            errors.rejectValue('emails', 'error.emails', 'Non unique e-mail')
            return false
        }
    }
}

我做了一些测试，结果他们以这种方式做得很好。