OCaml - 从一维数组转换为二维数组

Question

我正在尝试在 OCaml 中将一维数组转换为二维数组。

在测试我写的函数时：

# to_array2d [|1;2;3;1;2;4;1;2;5|];;

我得到这个错误的结果：

int array array = [|[|1; 2; 5|]; [|1; 2; 5|]; [|1; 2; 5|]|]

正确的结果应该是：

int array array = [|[|1; 2; 3|]; [|1; 2; 4|]; [|1; 2; 5|]|]

代码如下：

let to_array2d (array1d: int array) : int array array = 
    let dim = int_of_float (sqrt (float (Array.length array1d))) in
        let array2d = Array.make dim (Array.make dim 0 ) in
            for i = 0 to (dim - 1) do 
                    for j = 0 to (dim - 1) do
                        array2d.(i).(j) <- (Array.get array1d (i * dim + j))
                    done
                done;
                array2d
;;

我做错了什么？

Answer 1

你的代码有问题的地方是

let b =
  Array.make dim (Array.make dim 0)

这不是你想要的。 b 这个名字不在你的代码中，但便于讨论。为了理解你所看到的，让我们用以下等效方式重写这段代码：

let b =
  let a = Array.make dim 0 in
  Array.make dim a

此代码生成一个长度为dim 的数组，其条目都是a。这些不是a 的副本，它们只是a，名称不同。在 OCaml 中表达这一点的正确方法是说这些结构物理上相等，== 运算符测试物理上的相等性。

# b.(0) == b.(1);;
true

物理相等是比结构相等更强的关系，由更常见的= 运算符测试。指定给定两个物理上相等的可变结构，如b.(0) 和b.(1)，其中任何一个的修改都会影响另一个，或者用documentation of the Pervasives module 的话来说：

val (==) : 'a -> 'a -> bool e1 == e2 测试 e1 和 e2 的物理相等性。在诸如引用、数组、字节序列、具有可变字段的记录和具有可变实例变量的对象等可变类型上，当且仅当e1 的物理修改也会影响e2 时，e1 == e2 为真。在非可变类型上，( == ) 的行为取决于实现；但是，可以保证e1 == e2 意味着比较e1 e2 = 0。

我们可以认为这是一种正式的方式来表示这两个结构“确实相同”。

如果您想修改代码的结构，可以利用Array.make_matrix 函数，该函数将生成一个新的二维数组。如果你厌倦了在 for 循环中调试错误，你可以使用更 ocaml-ish 的解决方案：

let unpack dim a =
  let line i =
    Array.init dim (fun j -> a.(i*dim + j))
  in
  Array.init dim line

let to_array2d a =
  let dim = int_of_float (sqrt (float (Array.length array1d))) in
  unpack dim a

另见

• What's the difference between "equal (=)" and "identical (==)" in ocaml?
• Does != have meaning in OCaml?

Answer 2

详细说明@ivg 的答案：Array.make 将采用您给它的值并将其放入新数组的所有元素中。对于具有结构的值（如数组），这意味着您最终会出现三个非常相同的值。

# let a = Array.make 3 (Array.make 4 0);;
 val a : int array array = [|[|0; 0; 0; 0|]; [|0; 0; 0; 0|]; [|0; 0; 0; 0|]|]
# a.(1).(3) <- 17;;
- : unit = ()
# a;;
- : int array array = [|[|0; 0; 0; 17|]; [|0; 0; 0; 17|]; [|0; 0; 0; 17|]|]
# 

您不希望出现完全相同的数组。你每次都想要一个不同的数组。为此，您可以使用Array.init（比如说）。

# let a = Array.init 3 (fun _ -> Array.make 4 0);;
val a : int array array = [|[|0; 0; 0; 0|]; [|0; 0; 0; 0|]; [|0; 0; 0; 0|]|]
# a.(1).(3) <- 17;;
- : unit = ()
# a;;
- : int array array = [|[|0; 0; 0; 0|]; [|0; 0; 0; 17|]; [|0; 0; 0; 0|]|]

Answer 3

您创建的二维数组不正确。 Array.make 只会复制第二个参数dim 次。所以，你有一个指向同一个数组的三个指针的数组。查看here 以获取有关如何正确烹饪数组的更多详细信息。使用Array.init 函数可以更好地编写您的特定案例

let to_array2d (array1d: int array) : int array array = 
  let dim = int_of_float (sqrt (float (Array.length array1d))) in
  Array.init dim (fun i -> Array.init dim (fun j -> array1d.(i * dim + j)))

虽然，我不喜欢 sqrting 长度的想法。

可以在OCaml Book 中找到对此问题的很好解释。查看第 68 页（pdf 的第 94 页）。