使用 xsl 将单个 XML 文档转换为多个文档答案

【问题标题】：Using xsl to transform single XML doc to multiple docs使用 xsl 将单个 XML 文档转换为多个文档
【发布时间】：2010-09-12 18:47:49
【问题描述】：

给定以下 xml 文档：

<XML>
<doc1>
</doc1>
<doc2>
</doc2>
<XML>

我希望使用 xsl 转换来生成 2 个 XML 文档：

<XML>
<doc1>
</doc1>
<XML>

和

<XML>
</doc2>
<doc2>
<XML>

这可能吗？

【问题讨论】：

嘿，Oded，你打败了我——在 iphone 上编辑 xml 不是那么容易！
好问题 (+1)。请参阅我对 XSLT 1.0 和 XSLT 2.0 解决方案的回答。

标签： xml xslt transform

【解决方案1】：

在 XSLT 1.0 中，不可能创建多个树作为任何转换的输出，但在 XSLT 2.0 中，这可以很容易地完成。

在 XSLT 1.0 中，可以使用 EXSLT 的 <exsl:document> 扩展元素。

或者，可以进行转换，即提供一个全局（和外部指定的）参数，其中包含必须提取到单个文档中的元素的元素名称：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pDocElement" select="'doc1'"/>

 <xsl:template match="/*/*">
  <xsl:if test="name()=$pDocElement">
   <xsl:apply-templates select="." mode="copy"/>
  </xsl:if>
 </xsl:template>

 <xsl:template match="node()" mode="copy">
  <xsl:copy-of select="."/>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

应用于此 XML 文档时（基于提供的文档）：

<t>
    <doc1>
  Doc 1 Content
    </doc1>
    <doc2>
  Doc 2 Content
    </doc2>
    <doc3>
  Doc 3 Content
    </doc3>
</t>

产生想要的结果：

<doc1>
  Doc 1 Content
</doc1>

您将为每个元素运行一次此转换，其子树应提取到单独的文档中。

这是一个 XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*" mode="copy">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/*[starts-with(name(),'doc')]">
  <xsl:result-document href="{name()}.xml">
   <xsl:apply-templates select="." mode="copy"/>
  </xsl:result-document>
 </xsl:template>

 <xsl:template match="/*">
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时（基于提供的文档）：

<t>
    <doc1>
  Doc 1 Content
    </doc1>
    <doc2>
  Doc 2 Content
    </doc2>
    <doc3>
  Doc 3 Content
    </doc3>
</t>

结果正确输出到三个文档：

Saxon 9.1.0.5J from Saxonica
Java version 1.6.0_21
Stylesheet compilation time: 868 milliseconds
Loading net.sf.saxon.event.MessageEmitter
Writing to file:/C:/Program%20Files/Java/jre6/bin/doc1.xml
Writing to file:/C:/Program%20Files/Java/jre6/bin/doc2.xml
Writing to file:/C:/Program%20Files/Java/jre6/bin/doc3.xml
Execution time: 151 milliseconds
Memory used: 11467936
NamePool contents: 18 entries in 18 chains. 6 prefixes, 6 URIs

【讨论】：

+1 很好的答案，包括没有扩展解决方案的 XSLT 1.0！

【解决方案2】：

我们曾经遇到过这个问题并通过稍微作弊解决了它：

步骤 1：创建一个包含不同 xml 脚本的大文件，这些脚本由程序指令或 cmets 分隔。第2步：使用程序将文件切割成单独的文件。

注意你的中间结果是无效的xml，但最终结果是有效的。

示例

<doc1>..<doc1>
<!-- SEP -->
<doc2>..<doc2>
<!-- SEP -->
<doc3>..<doc3>

【讨论】：