Comonads 是否适合为 Wumpus 世界建模？

Question

我正在尝试找到一些comonad 的实际应用，我想我会尝试看看我是否可以将经典的Wumpus 世界表示为comonad。

我想使用此代码让 Wumpus 在世界中左右移动并清理脏瓷砖并避开坑。似乎唯一有用的comonad函数是extract（获取当前图块），而移动和清理图块将无法使用扩展或复制。

我不确定comonads 是否合适，但我看过一个演讲(Dominic Orchard: A Notation for Comonads)，其中comonads 用于对二维矩阵中的光标进行建模。

如果comonad 是代表Wumpus 世界的好方法，您能否说明我的代码哪里出错了？如果错了，您能否建议一个简单的共单子应用程序？

module Wumpus where

-- Incomplete model of a world inhabited by a Wumpus who likes a nice
-- tidy world but does not like falling in pits.

import Control.Comonad

-- The Wumpus world is made up of tiles that can be in one of three
-- states.
data Tile = Clean | Dirty | Pit
  deriving (Show, Eq)

-- The Wumpus world is a one dimensional array partitioned into three
-- values: the tiles to the left of the Wumpus, the tile occupied by
-- the Wumpus, and the tiles to the right of the Wumpus.
data World a = World [a] a [a]
  deriving (Show, Eq)

-- Applies a function to every tile in the world
instance Functor World where
  fmap f (World as b cs) = World (fmap f as) (f b) (fmap f cs)

-- The Wumpus world is a Comonad
instance Comonad World where
  -- get the part of the world the Wumpus currently occupies
  extract (World _ b _) = b
  -- not sure what this means in the Wumpus world.  This type checks
  -- but does not make sense to me.
  extend f w@(World as b cs) = World (map world as) (f w) (map world cs)
      where world v = f (World [] v [])

-- returns a world in which the Wumpus has either 1) moved one tile to
-- the left or 2) stayed in the same place if the Wumpus could not move
-- to the left.
moveLeft :: World a -> World a
moveLeft w@(World [] _ _) = w
moveLeft (World as b cs) = World (init as) (last as) (b:cs)

-- returns a world in which the Wumpus has either 1) moved one tile to
-- the right or 2) stayed in the same place if the Wumpus could not move
-- to the right.
moveRight :: World a -> World a
moveRight w@(World _ _ []) = w
moveRight (World as b cs) = World (as ++ [b]) (head cs) (tail cs)

initWorld = World [Dirty, Clean, Dirty] Dirty [Clean, Dirty, Pit]

-- cleans the current tile
cleanTile :: Tile -> Tile
cleanTile Dirty = Clean
cleanTile t = t

谢谢！

Answer 1

我会将我的一串 cmets 移到一个更连贯的答案..

你所拥有的实际上是一个“拉链”，特别是一个列表的拉链

data ListZip a = ListZip {lefts   :: [a]
                         ,focus   ::  a
                         ,rights  :: [a]}

我们可以将非空列表转换为ListZip

toZip :: [a] -> Maybe (ListZip a)
toZip (x:xs) = Just $ ListZip [] x xs
toZip  _     = Nothing

像所有拉链一样，ListZip 有一个重点，我们可以在这个重点领域开展工作

modifyFocus :: (a -> a) -> ListZip a -> ListZip a
modifyFocus f z = z{focus = f $ focus z}

我们可以将焦点转移到你所说的 moveLeft 和 moveRight

moveLeft, moveRight :: ListZip a -> ListZip a

moveLeft  (ListZip (x:xs) y ys) = ListZip xs x (y : ys)
moveRight (ListZip xs x (y:ys)) = ListZip (x : xs) y ys

现在就像所有的拉链一样，ListZip 是一个comonad！

extract提取焦点，或者当前占据的方格

instance Comonad ListZip where
  extract = focus

而extend返回一个新世界，我们根据“规则”修改了每个焦点方块。

  extend f w = ListZip (moving moveLeft) (f w) (moving moveRight)
    where moving i = map f $ iterate i w

在这种情况下，规则是一个函数

ZipList a -> a

如果这让您隐约想起了元胞自动机，那就对了！这与 Conway 的 Game of Life 等游戏的运作方式非常相似：简单的上下文相关规则。

我们还定义了duplicate，它将返回ListZip 的Listzip，其中焦点已在每个ListZip 上朝任何可能的方向移动。

现在我不知道这在 Wumpus 的上下文中到底有什么用处，您可以对板上的每个方格进行任何统一的转换吗？您能否从能够将 Wumpus 世界具体化为所有可能的 Wumpus 世界的 Wumpus 世界中受益？

这就是comonads在这种情况下给你的。