如何获取 Perl/Tk 中键的状态？答案

【问题标题】：How to get the state of a key in Perl/Tk?如何获取 Perl/Tk 中键的状态？
【发布时间】：2013-09-26 21:55:56
【问题描述】：

在 Perl/Tk 中，可以像这样绑定事件：

$mw->bind('<KeyPress-W>', sub{print "W is pressed";});

是否有可能从另一个方向获取此信息？我可以拨打“获取按键状态”或“检查是否按下 W”之类的电话吗？

它不会直接对事件做出反应。

当然，有可能为各种事件填充变量，但我想知道是否有这样的方法。

【问题讨论】：

你可以绑定一个在你的程序中设置控制标志的事件，但是我不知道另一种方法。

标签： perl tk perltk

【解决方案1】：

Perl/Tk 不提供这样的功能。因此，您必须自己跟踪事件。请注意，有 Any-KeyPress 和 Any-KeyRelease 事件，因此您不必为每个键创建绑定：

$mw->bind("<Any-KeyPress>" => sub {
    warn $_[0]->XEvent->K; # prints keysym
});

如果您使用的是 X11，那么使用 X11::Protocol 模块（可在 Perl/Tk 脚本中使用）并调用 QueryKeymap 方法将为您提供实际按下的键码。这是一个演示此的小脚本：

use strict;
use X11::Protocol;

# Get the keycode-to-keysym mapping. Being lazy, I just parse
# the output of xmodmap -pke. The "real" approach would be to
# use X11 functions like GetKeyboardMapping() and the
# X11::Keysyms module.
my %keycode_to_keysym;
{
    open my $fh, "-|", "xmodmap", "-pke" or die $!;
    while(<$fh>) {
        chomp;
        if (m{^keycode\s+(\d+)\s*=(?:\s*(\S+))?}) {
            if (defined $2) {
                $keycode_to_keysym{$1} = $2;
            }
        } else {
            warn "Cannot parse $_";
        }
    }
}

my $x11 = X11::Protocol->new;
while(1) {
    my $keyvec = $x11->QueryKeymap;
    for my $bit (0 .. 32*8-1) {
        if (vec $keyvec, $bit, 1) {
            warn "Active key: keycode $bit, keysym $keycode_to_keysym{$bit}\n";
        }
    }
    sleep 1;
}

【讨论】：