Perl（tk）：如何异步运行系统命令，能够对其输出做出反应？

Question

我正在使用 Perl “Tk” 为外部命令（“sox”，如果有帮助的话）编写一个包装器。 当然，我需要异步运行它，以避免阻塞 tk 的 MainLoop()。 但是，我需要阅读它的输出来通知用户命令的进度。

我正在使用 IPC::Open3 测试这样的解决方案：

{
    $| = 1;
    $pid = open3(gensym, ">&STDERR", \*FH, $cmd) or error("Errore running command \"$cmd\"");
}
while (defined($ch = FH->getc)) {
    notifyUser($ch) if ($ch =~ /$re/);
}
waitpid $pid, 0;
$retval = $? >> 8;
POSIX::close($_) for 3 .. 1024; # close all open handles (arbitrary upper bound)

当然，while 循环会阻塞 MainLoop，直到 $cmd 确实终止。

有什么方法可以异步读取输出句柄吗？ 还是我应该使用标准叉子？ 该解决方案也应该在win32下工作。

Answer 1

对于文件句柄的非阻塞读取，请查看Tk::fileevent。

这是一个示例脚本，如何一起使用管道、分叉进程和文件事件：

use strict;
use IO::Pipe;
use Tk;

my $pipe = IO::Pipe->new;
if (!fork) { # Child XXX check for failed forks missing
    $pipe->writer;
    $pipe->autoflush(1);
    for (1..10) {
        print $pipe "something $_\n";
        select undef, undef, undef, 0.2;
    }
    exit;
}
$pipe->reader;

my $mw = tkinit;
my $text;
$mw->Label(-textvariable => \$text)->pack;
$mw->Button(-text => "Button", -command => sub { warn "Still working!" })->pack;
$mw->fileevent($pipe, 'readable', sub {
                   if ($pipe->eof) {
                       warn "EOF reached, closing pipe...";
                       $mw->fileevent($pipe, 'readable', '');
                       return;
                   }
                   warn "pipe is readable...\n";
                   chomp(my $line = <$pipe>);
                   $text = $line;
               });
MainLoop;

分叉在 Windows 下可能工作也可能不工作。在 Tk 内分叉时也需要谨慎；你必须确保两个进程中只有一个在做 X11/GUI 的东西，否则会发生不好的事情（X11 错误、崩溃......）。一个好的方法是在创建 Tk MainWindow 之前进行 fork。