如何使用 XSLT1 按标签折叠一组选定（邻居）标签？

Question

我有一组必须包含在新元素中的顺序节点。示例：

  <root>
    <c>cccc</c>
    <a gr="g1">aaaa</a>    <b gr="g1">1111</b>
    <a gr="g2">bbbb</a>   <b gr="g2">2222</b>
  </root>

必须用 fold 标记括起来，结果（在 XSLT 之后）为：

  <root>
    <c>cccc</c>
    <fold><a gr="g1">aaaa</a>    <b gr="g1">1111</b></fold>
    <fold><a gr="g2">bbbb</a>   <b gr="g2">2222</b></fold>
  </root>

所以，我有一个“分组标签”（@gr）但不知道如何生成正确的折叠标签。

---

我正在尝试使用this question 或this other one 的线索...但是我有一个“分组标签”，所以我知道我的解决方案不需要使用key() 函数。

我的非通用解决方案是：

   <xsl:template match="/">
       <root>
       <xsl:copy-of select="root/c"/>
       <fold><xsl:for-each select="//*[@gr='g1']">
             <xsl:copy-of select="."/>
       </xsl:for-each></fold>

       <fold><xsl:for-each select="//*[@gr='g2']">
             <xsl:copy-of select="."/>
       </xsl:for-each></fold>

       </root>
   </xsl:template>

我需要一个通用解决方案 (!)，循环所有 @gr 并处理（身份）所有没有 @gr 的上下文...也许使用 身份转换。

另一个（未来的）问题是递归地执行此操作，折叠折叠。

Answer 1

在 XSLT 1.0 中，处理这类事情的标准技术称为 Muenchian 分组，它涉及使用定义节点应如何分组的 key 以及使用 generate-id 的技巧仅提取每个组中的第一个节点作为整个组的代理。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:strip-space elements="*" />
  <xsl:output indent="yes" />
  <xsl:key name="elementsByGr" match="*[@gr]" use="@gr" />

  <xsl:template match="@*|node()" name="identity">
    <xsl:copy><xsl:apply-templates select="@*|node()"/></xsl:copy>
  </xsl:template>

  <!-- match the first element with each @gr value -->
  <xsl:template match="*[@gr][generate-id() =
         generate-id(key('elementsByGr', @gr)[1])]" priority="2">
    <fold>
      <xsl:for-each select="key('elementsByGr', @gr)">
        <xsl:call-template name="identity" />
      </xsl:for-each>
    </fold>
  </xsl:template>

  <!-- ignore subsequent ones in template matching, they're handled within
       the first element template -->
  <xsl:template match="*[@gr]" priority="1" />
</xsl:stylesheet>

这实现了您所追求的分组，但就像您的非通用解决方案一样，它不会保留 a 和 b 元素之间的缩进和空白文本节点，即它会给你

<root>
  <c>cccc</c>
  <fold>
    <a gr="g1">aaaa</a>
    <b gr="g1">1111</b>
  </fold>
  <fold>
    <a gr="g2">bbbb</a>
    <b gr="g2">2222</b>
  </fold>
</root>

---

请注意，如果您能够使用 XSLT 2.0，那么整个事情就变成了一个 for-each-group：

<xsl:template match="root">
  <xsl:for-each-group select="*" group-adjacent="@gr">
    <xsl:choose>
      <!-- wrap each group in a fold -->
      <xsl:when test="@gr">
        <fold><xsl:copy-of select="current-group()" /></fold>
      </xsl:when>
      <!-- or just copy as-is for elements that don't have a @gr -->
      <xsl:otherwise>
        <xsl:copy-of select="current-group()" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:for-each-group>
</xsl:template>