创建 TGZ 存档时更改布局

Question

我使用 CMake 管理具有以下布局的项目：

ProjectA/
  include
  doc
  test
ProjectB
  include
  doc
  test

我想使用 CPack 打包一个 tar.gz source 存档，其布局如下：

include/
ProjectA/
  doc
  test
ProjectB/
  doc
  test

新的顶级包含包含所有包含文件。

我尝试通过CPACK_INSTALL_SCRIPT 运行 CMake 脚本来实现此目的，但此脚本在文件创建之前运行。我在哪里可以连接到 CPack 以获得这种效果？

似乎install 对make package_source 的作用没有影响，但它对make package 有影响。不幸的是make package 也将构建和打包 图书馆，这是我不想发生的事情。我想要一个纯粹的 源代码分发ala make dist.

Answer 1

您可以在 ProjectA 和 ProjectB 的标头上调用 install(DIRECTORY include DESTINATION include) 并将它们安装到同一个目录中。这将导致 CPack 将它们一起放在生成的包中。

更新

好的，我已经用CPACK_INSTALL_SCRIPT 变量做到了。

我创建了以下脚本：

set(CMAKE_SOURCE_DIR @CMAKE_SOURCE_DIR@)

execute_process(COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/A/ ${CMAKE_SOURCE_DIR})
execute_process(COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/B/ ${CMAKE_SOURCE_DIR})
execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_SOURCE_DIR}/A)
execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_SOURCE_DIR}/B)

在CMakeLists.txt 中，我用CMAKE_SOURCE_DIR 的实际值填充了它：

configure_file(CPackScript.cmake CPackScript.cmake @ONLY)

最后，我添加了set(CPACK_INSTALL_SCRIPT ${CMAKE_BINARY_DIR}/CPackScript.cmake)，瞧！生成的包现在具有include 目录，其中包含来自A/ 和B/ 的标头，而A/ 和B/ 目录不存在。

Answer 2

另一种可能的方法是完全绕过 CPack 来生成 TGZ 存档，并简单地使用生成存档的 CMake 自定义目标：

project (MyProject)

set (DIST_TEMP_DIR "${CMAKE_BINARY_DIR}/dist")
make_directory(${DIST_TEMP_DIR})

add_custom_target(dist 
    COMMAND ${CMAKE_COMMAND} -E remove_directory "${DIST_TEMP_DIR}/${PROJECT_NAME}/"
    COMMAND ${CMAKE_COMMAND} -E copy_directory "${CMAKE_CURRENT_SOURCE_DIR}/ProjectA/include" "${DIST_TEMP_DIR}/${PROJECT_NAME}/include"
    COMMAND ${CMAKE_COMMAND} -E copy_directory "${CMAKE_CURRENT_SOURCE_DIR}/ProjectA/test" "${DIST_TEMP_DIR}/${PROJECT_NAME}/ProjectA/test"
    COMMAND ${CMAKE_COMMAND} -E copy_directory "${CMAKE_CURRENT_SOURCE_DIR}/ProjectA/doc" "${DIST_TEMP_DIR}/${PROJECT_NAME}/ProjectB/doc"
    COMMAND ${CMAKE_COMMAND} -E copy_directory "${CMAKE_CURRENT_SOURCE_DIR}/ProjectB/include" "${DIST_TEMP_DIR}/${PROJECT_NAME}/include"
    COMMAND ${CMAKE_COMMAND} -E copy_directory "${CMAKE_CURRENT_SOURCE_DIR}/ProjectB/doc" "${DIST_TEMP_DIR}/${PROJECT_NAME}/ProjectA/doc"
    COMMAND ${CMAKE_COMMAND} -E copy_directory "${CMAKE_CURRENT_SOURCE_DIR}/ProjectB/test" "${DIST_TEMP_DIR}/${PROJECT_NAME}/ProjectB/test"
    COMMAND ${CMAKE_COMMAND} -E tar cvz "${CMAKE_BINARY_DIR}/${PROJECT_NAME}.tar.gz"  "${DIST_TEMP_DIR}/${PROJECT_NAME}/"
    COMMENT "Building ${PROJECT_NAME}.tar.gz"
    WORKING_DIRECTORY "${DIST_TEMP_DIR}"
)

自定义目标 dist 首先通过在命令模式下使用多个 copy_directory 命令调用 CMake，在构建文件夹内的临时目录中设置所需的存档结构。然后使用tar命令模式子命令生成tar.gz归档。

Answer 3

我不确定究竟是什么不适合你。

这对我来说适用于 Windows 上的 ZIP 生成器。我将尝试找到一台 linux 机器，看看这是否也适用于 TGZ（编辑：确实如此）：

目录结构：

CMakeLists.txt
ProjectA/
    doc
        foo.txt
    include
        foo.h
    test
        foo.test
ProjectB/
    doc
        bar.txt
    include
        bar.h
    test
        bar.test

ProjectA/CMakeLists.txt

project( ProjectA )

INSTALL( DIRECTORY include DESTINATION . )
INSTALL( DIRECTORY doc DESTINATION ${PROJECT_NAME}/ )
INSTALL( DIRECTORY test DESTINATION ${PROJECT_NAME}/ )

ProjectB/CMakeLists.txt

project( ProjectB )

INSTALL( DIRECTORY include DESTINATION . )
INSTALL( DIRECTORY doc DESTINATION ${PROJECT_NAME}/ )
INSTALL( DIRECTORY test DESTINATION ${PROJECT_NAME}/ )

CMakeLists.txt：

project( MyProject )

ADD_SUBDIRECTORY(ProjectA)
ADD_SUBDIRECTORY(ProjectB)

INCLUDE(CPack)

如果我创建包，我会得到

MyProject-0.1.1-win32.zip
    MyProject-0.1.1-win32
        include
            bar.h
            foo.h
        ProjectA
            doc
                foo.txt
            test
                foo.test
        ProjectB
            doc
                bar.txt
            test
                bar.test

这是你想要的吗？

源包

对于源包创建，CPack 默认忽略安装命令并安装/复制所有在CPACK_SOURCE_INSTALLED_DIRECTORIES 中指定的目录。此变量包含成对的源目录和目标目录。如果未手动设置，则默认为"${CMAKE_SOURCE_DIR};/"。准确地说，它会覆盖这些目录，忽略 CPACK_SOURCE_IGNORE_FILES 中的所有文件，这些文件默认为所有主要的 VCS 簿记文件（例如，请参阅您的 CPackSourceConfig.cmake）。

您可以执行以下操作：

CMakeLists.txt

project( MyProject )

SET( PROJECTS ProjectA ProjectB )

SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_CURRENT_SOURCE_DIR};/") 
FOREACH( p ${PROJECTS} ) 
    ADD_SUBDIRECTORY( ${p} )
    LIST( APPEND CPACK_SOURCE_INSTALLED_DIRECTORIES ${CMAKE_CURRENT_SOURCE_DIR/${p}/include include )
ENDFOREACH()


INCLUDE(CPack)

或将CPACK_SOURCE_INSTALLED_DIRECTORIES 的操作添加到相应的项目文件中。

但是：这会将您的包含目录安装到顶级包含目录，但由于通配，仍会在项目目录中创建另一个副本。您可能会为您的doc 和test 目录创建额外的目录对，并在SET 命令中跳过CPACK_SOURCE_INSTALLED_DIRECTORIES 的初始化。如果这样做，您将需要找到一种方法来安装/复制特定于项目的 CMake 文件。

BIG CAVEAT：如果ProjectA或ProjectB引用项目本地包含目录（例如，使用INCLUDE_DIRECTORIES(...)，您将破坏您的CMake代码，呈现源安装（部分）没用。所以你可能要重新考虑你对顶级包含目录的想法。