检索 CMake 中的所有链接标志

Question

在 CMake 中，是否可以以编程方式检索将用于给定目标的链接器标志的完整列表？我能看到的唯一方法是检查目标的CMakeFiles 目录中的link.txt 文件。不理想。

我感兴趣的用例是收集数据以包含在 pkg-config 文件之类的文件中。我正在编写一个库，它包含几个使用该库的可执行实用程序。构建可执行文件（尤其是静态构建库时）需要一个重要的链接行来链接到我的库及其依赖项。所以我想写出将这些可执行文件构建到包中包含的数据文件所需的链接行，以便其他客户端可以知道如何链接。

Answer 1

正如@Tsyvarev 所评论的那样，CMake 中没有内置命令或属性“以编程方式检索链接器标志的完整列表”。

但受到您的提示的启发“所以我想写出将这些可执行文件构建到数据文件所需的链接行”我想我找到了一个可行的解决方案（至少对于 makefile 生成器） )。

如果我正确理解了您的要求，我们并不是在谈论像您这样简单的详细输出，例如CMAKE_VERBOSE_MAKEFILE，这仍然需要你手动复制。

所以考虑以下几点：

• 需要先运行生成器才能得到真正的链接线
• CMake 允许您按名称发明任何链接器语言
• 您可以使用变量和expansion rules 定义与CMAKE_>LANG<_LINK_EXECUTABLE 的链接线

我想出使用我的ECHO“链接器”添加一个LinkLine 可执行文件，其唯一目的是创建我选择的链接行文件：

set(CMAKE_ECHO_STANDARD_LIBRARIES ${CMAKE_CXX_STANDARD_LIBRARIES})
set(CMAKE_ECHO_FLAGS ${CMAKE_CXX_FLAGS})
set(CMAKE_ECHO_LINK_FLAGS ${CMAKE_CXX_LINK_FLAGS})
set(CMAKE_ECHO_IMPLICIT_LINK_DIRECTORIES ${CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES})
set(
    CMAKE_ECHO_LINK_EXECUTABLE 
    "<CMAKE_COMMAND> -E echo \"<FLAGS> <LINK_FLAGS> <LINK_LIBRARIES>\" > <TARGET>"
)

add_executable(LinkLine "")
target_link_libraries(LinkLine MyLibraryTarget)

set_target_properties(
    LinkLine 
        PROPERTIES
            LINKER_LANGUAGE ECHO
            SUFFIX          ".txt"
)

这种方法的好处是，我的LinkLine 目标的输出可以用作任何其他“官方生成”的可执行输出（例如在install() commands 或generator expressions 的构建后步骤中）：

add_custom_command(
    TARGET LinkLine
    POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:LinkLine> PackageCfg/$<TARGET_FILE_NAME:LinkLine>
)

参考文献

• Recursive list of LINK_LIBRARIES in CMake
• add_custom_command is not generating a target