OCaml 模块类型和单独编译

Question

我正在阅读OCaml lead designer's 1994 paper on modules, types, and separate compilation.（Norman Ramsey 在another question 中向我指出）。我知道这篇论文讨论了 OCaml 当前模块类型/签名系统的起源。因此，作者建议对签名中的类型声明（以允许单独编译）以及清单类型声明（为了表达性）进行不透明的解释。尝试整理我自己的一些示例来演示 OCaml 模块签名表示法试图解决的问题类型，我在两个文件中编写了以下代码：

在文件ordering.ml（或.mli——我都试过了）（文件A）：

module type ORDERING = sig
 type t
 val isLess : t -> t -> bool
end

在文件useOrdering.ml（文件 B）中：

open Ordering
module StringOrdering : ORDERING
  let main () =
    Printf.printf "%b" StringOrdering.isLess "a" "b"
  main ()

这个想法是期望编译器抱怨（在编译第二个文件时）模块 StringOrdering 上没有足够的类型信息来对 StringOrdering.isLess 应用程序进行类型检查（从而激发对 with type 语法的需求）。 但是，尽管文件 A 可以按预期编译，但文件 B 会导致 3.11.2 ocamlc 抱怨语法错误。我理解签名的目的是允许某人根据模块签名编写代码，而无需访问实现（模块结构）。

我承认我不确定我在this rather old paper on separate compilation 中遇到的语法：module A : B，但这让我想知道是否存在这样或类似的语法（不涉及函子）以允许某人仅基于模块类型，链接时提供的实际模块结构，类似于在 C/C++ 中使用*.h 和*.c 文件的方式。如果没有这种能力，似乎模块类型/签名基本上是用于密封/隐藏模块内部或更明确的类型检查/注释，而不是用于单独/独立编译。

实际上，看着OCaml manual section on modules and separate compilation，我与C 编译单元的类比似乎被打破了，因为OCaml 手册将OCaml 编译单元定义为A.ml 和A.mli 二重奏，而在C/C++ 中@ 987654342@ 文件被粘贴到任何导入的.c 文件的编译单元。

Answer 1

这样做的正确方法是执行以下操作：

1. 在 ordering.mli 中写：

   (* This define the signature *)
   module type ORDERING = sig
     type t
     val isLess : t -> t -> bool
   end
   
   (* This define a module having ORDERING as signature *)
    module StringOrdering : ORDERING
   

2. 编译文件：ocamlc -c ordering.mli

3. 在另一个文件中，参考编译后的签名：

   open Ordering
   
   let main () =
     Printf.printf "%b" (StringOrdering.isLess "a" "b")
   
   let () = main ()
   

   编译文件时，您会收到预期的类型错误（即string 与Ordering.StringOrdering.t 不兼容）。如果要消除类型错误，应在ordering.mli 中StringOrdering 的定义中添加with type t = string 约束。

所以回答你第二个问题：是的，在字节码模式下，编译器只需要知道你所依赖的接口，你可以选择在链接时使用哪个实现。默认情况下，本机代码编译并非如此（因为模块间优化），但您可以禁用它。

Answer 2

您可能只是对显式模块和签名定义之间的关系以及通过 .ml/.mli 文件隐式定义模块之间的关系感到困惑。

基本上，如果你有一个文件 a.ml 并在其他文件中使用它，那么就好像你已经写了

module A =
struct
  (* content of file a.ml *)
end

如果你也有a.mli，那就像你写的一样

module A :
sig
  (* content of file a.mli *)
end =
struct
  (* content of file a.ml *)
end

注意这里只定义了一个名为A的模块，而不是一个模块type。 A 的签名不能通过这种机制命名。

另一个使用 A 的文件可以单独针对 a.mli 进行编译，根本不需要提供 a.ml。但是，您要确保所有类型信息在需要时都是透明的。例如，假设您要定义一个整数映射：

(* intMap.mli *)
type key = int
type 'a map
val empty : 'a map
val add : key -> 'a -> 'a map -> 'a map
val lookup : key -> 'a map -> 'a option
...

这里，key 是透明的，因为任何客户端代码（该签名描述的模块 IntMap）都需要知道它是什么才能向地图添加内容。然而，map 类型本身可以（并且应该）保持抽象，因为客户端不应该弄乱它的实现细节。

与C 头文件的关系是那些基本上仅 允许透明类型。在 Ocaml 中，您可以选择。

Answer 3

module StringOrdering : ORDERING 是一个模块声明。您可以在签名中使用它，表示签名包含一个名为StringOrdering 的模块字段并具有签名ORDERING。在模块中没有意义。

您需要在某个地方定义一个模块来实现您需要的操作。模块定义可以类似于

module StringOrderingImplementation = struct
  type t = string
  let isLess x y = x <= y
end

如果你想隐藏类型t的定义，你需要创建一个不同的模块，其中定义是抽象的。将旧模块变成新模块的操作称为密封，通过: 运算符表示。

module StringOrderingAbstract = (StringOrdering : ORDERING)

那么StringOrderingImplementation.isLess "a" "b" 是正确类型的，而StringOrderingAbstract.isLess "a" "b" 不能被类型化，因为StringOrderingAbstract.t 是一个抽象类型，它与string 或任何其他预先存在的类型不兼容。事实上，不可能构建StringOrderingAbstract.t 类型的值，因为模块不包含任何构造函数。

当你有一个编译单元foo.ml时，它就是一个模块Foo，这个模块的签名由接口文件foo.mli给出。即文件foo.ml和foo.mli等价于模块定义

module Foo = (struct (*…contents of foo.ml…*) end :
              sig (*…contents of foo.mli…*) end)

在编译使用Foo 的模块时，编译器只查看foo.mli（或者更确切地说是其编译结果：foo.cmi），而不是foo.ml¹。这就是接口和单独编译如何结合在一起的方式。 C 需要#include <foo.h>，因为它缺少任何形式的命名空间；在 OCaml 中，Foo.bar 自动引用在编译单元 foo 中定义的 bar，如果范围内没有其他名为 Foo 的模块。

¹ _{实际上，本机代码编译器查看Foo 的实现以执行优化（内联）。类型检查器只查看界面中的内容。}