打开两个文本文件，处理它们并写入单独的文件

Question

我正在使用 Perl 打开两个文本文件，处理它们，然后将输出写入另一个文件。

我有一个文件INPUT，每一行都是客户。我会将每一行处理成变量，这些变量将用于替换另一个文件TEMP 中的文本。应将结果写入每个客户的单独文件中，OUTPUT。

我的程序似乎只处理第一个文件。其余文件保持为空，没有输出。

#!/usr/bin/perl -w

if ( $#ARGV < 0) {
    print "Usage: proj5.pl <mm/dd/yyyy>\n";
    exit;
}

my $date = $ARGV[0];

open(INFO, "p5Customer.txt") or die("Could not open p5Customer.txt file\n");
open(TEMP, "template.txt")   or die("Could not open template.txt file\n");

my $directory = "Emails";
mkdir $directory unless(-e $directory);

foreach $info (<INFO>){

    ($email, $fullname, $title, $payed, $owed) = split /,/, $info;
    next if($owed < $payed);
    chomp($owed);

    $filepath = "$directory/$email";
    unless(open OUTPUT, '>>'.$filepath){
        die "Unable to create '$filepath'\n";
    }

    foreach $detail (<TEMP>){
        $detail =~ s/EMAIL/$email/g;
        $detail =~ s/(NAME|FULLNAME)/$fullname/g;
        $detail =~ s/TITLE/$title/g;
        $detail =~ s/AMOUNT/$owed/g;
        $detail =~ s{DATE}{$date}g;
        print OUTPUT $detail;
    }

    close(OUTPUT);
}

close(INFO);
close(TEMP);

Answer 1

如前所述，每次读取模板文件时都需要再次打开它。你的代码还有很多其他问题

• 总是use strict 和use warnings 'all' 并用my 声明每个变量，使其尽可能接近首次使用的位置

• $#ARGV是@ARGV的最后一个元素的索引，所以$#ARGV < 0写成@ARGV < 1会好很多

• 你应该使用词法文件句柄，并且open的三参数形式，所以open(INFO, "p5Customer.txt")应该是open my $info_fh, '<', "p5Customer.txt"

• 你应该使用while而不是for来读取文件

• 使用默认变量$_进行短循环更容易

• 如果你不打算使用正则表达式中的子字符串是没有意义的，所以(NAME|FULLNAME)应该是NAME|FULLNAME

• 在程序结束之前关闭输入文件是没有意义的

使用现有的模板系统也更好，例如 Template::Toolkit

这应该适合你

#!/usr/bin/perl

use strict;
use warnings 'all';

if ( @ARGV < 1 ) {
    print "Usage: proj5.pl <mm/dd/yyyy>\n";
    exit;
}

my $date = $ARGV[0];

open my $info_fh, '<', 'p5Customer.txt' or die qq{Could not open "p5Customer.txt" file: $!};

my $directory = "Emails";
mkdir $directory unless -e $directory;

while ( <$info_fh> ) {

    chomp;
    my ($email, $fullname, $title, $payed, $owed) = split /,/;
    next if $owed < $payed;

    open my $template_fh, '<', 'template.txt' or die qq{Could not open "template.txt" file: $!};

    my $filepath = "$directory/$email";
    open my $out_fh, '>', $filepath or die qq{Unable to create "$filepath": $!};

    while ( <$template_fh> ) {

        s/EMAIL/$email/g;
        s/FULLNAME|NAME/$fullname/g;
        s/TITLE/$title/g;
        s/AMOUNT/$owed/g;
        s/DATE/$date/g;

        print $out_fh $_;
    }

    close($out_fh);
}

Answer 2

您的问题是 TEMP 循环在 inside INPUT 循环中，因此当 INPUT 循环仍在 INPUT 文件的第一行时，TEMP 循环将结束。

最好将 TEMP 文件数据存储到哈希表中，并在 INPUT 循环内处理 TEMP 哈希表。

祝你好运。