批量跳过 WMIC 命令输出的最后一个空行

Question

我正在尝试将 JSON 中的命令输出格式化为：

echo "patches" : {
set patches="wmic qfe get HotfixID"
for /f "skip=1" %%i in (' %patches% ') do (
    set /a count=count+1
    call echo "!count!" : "%%i",
)
echo }

一切都很好，直到我到达补丁列表的末尾，它读取最后一个补丁之后的行，然后打印""。

我怎样才能让它在它应该停止的时候停止？

如果可能，我想避免使用文本文件。

Answer 1

在for /f 循环内，放置另一个：

for /f "skip=1" %%i in ('%patches%') do for /f "delims=" %%j in ("%%i") do (
    rem // use `%%j` in the loop body
)

wmic 命令返回 Unicode 输出。由于for /f 不适合处理此类问题，它会产生像孤立的回车符 (CR) 这样的伪影，从而导致您遇到的效果（最后一行在您的 for /f %%i 循环中不会显示为空，因为它包含这样的 CR；请记住for /f 会跳过真正空的行）。在内部放置另一个 for /f 循环，因此对每个项目进行双重处理会删除此类伪影。

这里是固定脚本：

echo "patches" : {
set "patches=wmic qfe get HotfixID"
for /f "skip=1" %%i in ('%patches%') do for /f "delims=" %%j in ("%%i") do (
    set /a count=count+1
    echo "!count!" : "%%j",
)
echo }

由于我没有得到call 命令的用途，所以我将其删除。

---

双重解析方法其实归功于dbenham——见他对Why is the FOR /f loop in this batch script evaluating a blank line?的回答以及他的外部文章WMIC and FOR /F : A fix for the trailing <CR> problem。

Answer 2

批量跳过WMIC命令输出的最后一个空行

最简单的解决方案是使用findstr 删除空行：

for /f "skip=1" %%i in ('%patches% ^| findstr /r /v "^$"')

不需要额外的for 循环。

---

进一步阅读

• An A-Z Index of the Windows CMD command line - 与 Windows cmd 行相关的所有内容的绝佳参考。
• findstr - 在文件中搜索字符串。