如何在 WebBrowser 控件中自动输入

Question

我在 vb.net 方面非常业余。当我在文本框中输入文本时，它应该能够在webbrowsercontrol上自动输入以及如何单击按钮登录，其中没有getelementbyid。

我也设法使第一部分正确，但是当我从浏览器内部单击登录按钮时，似乎有一个小错误。很久以前做过一个这样的项目，现在找不到源代码了，所以我又从头开始了。

网址：https://app.coins.ph/welcome/login

到目前为止，这是我的代码：

Private Sub TextBox1_TextChanged(sender As Object, e As EventArgs) Handles TextBox1.TextChanged
    WebBrowser1.Document.GetElementById("username").InnerText = TextBox1.Text
End Sub

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    For Each Element As HtmlElement In WebBrowser1.Document.GetElementsByTagName("class") 'Depending on how the source code is formatted on the tag, you may also try Element.OuterHTML, Element.InnerText and Element.OuterText in the line below
        If Element.OuterText.Contains("SIGN IN") Then
            Element.InvokeMember("click")
            Exit For
        End If
    Next Element
End Sub

Private Sub TextBox2_TextChanged(sender As Object, e As EventArgs) Handles TextBox2.TextChanged
    WebBrowser1.Document.GetElementById("password").InnerText = TextBox2.Text
End Sub

Answer 1

这里有几个问题。让我们从文本框输入开始。如果您查看该网站登录页面的 html 源代码，用户名和密码的输入没有 ID 属性，它们仅使用名称。此外，GetElementsByTagName 正在搜索“用户名”的 html 元素，而不是应有的“输入”。鉴于这两个问题，您应该使用Document.All("[elementName]") 来访问这些输入。至于登录部分，如前所述，GetElementsByTagName 正在寻找 html 元素，因此搜索值“class”不会返回您想要的任何内容。相反，您应该寻找 OuterText 包含“SIGN IN”的“按钮”。应用所有这些更改后，代码变为：

Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        WebBrowser1.Navigate("https://app.coins.ph/welcome/login")
    End Sub

    Private Sub TextBox1_TextChanged(sender As Object, e As EventArgs) Handles TextBox1.TextChanged
        WebBrowser1.Document.All("username").InnerText = TextBox1.Text
    End Sub

    Private Sub TextBox2_TextChanged(sender As Object, e As EventArgs) Handles TextBox2.TextChanged
        WebBrowser1.Document.All("password").InnerText = TextBox2.Text
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        For Each Element As HtmlElement In WebBrowser1.Document.GetElementsByTagName("button")
            If Element.OuterText.Contains("SIGN IN") Then
                Element.InvokeMember("click")
                Exit For
            End If
        Next Element
    End Sub

End Class

运行此代码后还有另一个问题

如果您运行上面的示例，您将看到表单域已正确填写并且成功单击了登录按钮，但是会出现一个错误，表明表单域仍然是空白的。即使您也使用WebBrowser1.Document.All("username").SetAttribute("value", TextBox1.Text) 设置输入值，也会发生相同的错误。这可能是因为该网站的开发人员正在使用某种 javascript 来检测按键，出于某种原因……不可能知道为什么，但事实就是如此。所以你只剩下自己实际模拟按键了。如果您这样做，该网站将使用用户名和密码成功登录。你有两种方法可以做到这一点。更简洁的方法是一次发送所有密钥并像这样登录：

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    WebBrowser1.Focus()
    WebBrowser1.Document.All("username").Focus()
    For Each c As Char In TextBox1.Text.ToCharArray
        SendKeys.SendWait(c)
    Next
    WebBrowser1.Document.All("password").Focus()
    For Each c As Char In TextBox2.Text.ToCharArray
        SendKeys.SendWait(c)
    Next
    For Each Element As HtmlElement In WebBrowser1.Document.GetElementsByTagName("button")
        If Element.OuterText.Contains("SIGN IN") Then
            Element.InvokeMember("click")
            Exit For
        End If
    Next Element
End Sub

但是，如果您仍然希望每个字符在您键入时出现，为了反映您当前使用的 TextChanged 事件逻辑的功能，您必须使用 KeyPress 事件并基本上像这样转发击键：

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    For Each Element As HtmlElement In WebBrowser1.Document.GetElementsByTagName("button")
        If Element.OuterText.Contains("SIGN IN") Then
            Element.InvokeMember("click")
            Exit For
        End If
    Next Element
End Sub

Private Sub TextBox1_KeyPress(sender As Object, e As KeyPressEventArgs) Handles TextBox1.KeyPress
    WebBrowser1.Focus()
    WebBrowser1.Document.All("username").Focus()
    SendKeys.SendWait(e.KeyChar)
    TextBox1.Focus()
End Sub

Private Sub TextBox2_KeyPress(sender As Object, e As KeyPressEventArgs) Handles TextBox2.KeyPress
    WebBrowser1.Focus()
    WebBrowser1.Document.All("password").Focus()
    SendKeys.SendWait(e.KeyChar)
    TextBox2.Focus()
End Sub