Cypher：如何在路径中匹配关系节点关系

Question

我是 Cypher 和 Neo4j（以及 Stack Overflow）的新手，所以希望这个问题有一个简单的答案。我花了几个小时阅读文档和谷歌搜索，但没有找到确切的答案来回答这个问题。

显然我需要更多的声望来发布图片，所以我会尽力使用文字。

我可以像这样找到从一个节点到另一个节点的路径：

    MATCH path = (a {name:"a"})-[*]-(x {name:"x"})
    RETURN extract(r IN nodes(path) | r);

这可能会返回如下两条路径：

    (a)-[:RED]->(b)<-[:BLUE]-(c)-[:RED]->(f)<-[:RED]-(g)-[:BLUE]->(h)<-[:RED]-(x)

    (z)-[:RED]->(h)<-[:RED]-(x)

到目前为止一切顺利。当然，数据库中还有很多其他关系和节点连接到这些节点，但这是正确的路径。

我需要沿着路径找到一个节点，其中有两个 RED 关系进入，如下所示：

    -[:RED]->(findme)<-[:RED]-

在上面的两个路径示例中，findme = (f) 和 (h)。

注意：数据库中会有很多匹配项，但我只想要路径中的一个（应该只有一个）。此外，路径中可能有许多节点和不同的关系，或者只有 3 个节点，每个节点都通过 RED 关系连接。

我尝试使用匹配：

    MATCH (a)-[*]-(b)-[:RED]->(findme)<-[:RED]-(c)-[*]-(x) RETURN findme;

只要有至少 5 个节点就可以工作，但不适用于 3 个节点。

如何在路径中找到这种模式匹配？

Answer 1

你很接近！如您所知，* 表示可变长度/深度。您可以像在查询中那样单独使用该符号，也可以指定一个范围。如果没有指定范围，* 表示“一个或多个”。如果您应用上一个查询

MATCH (a)-[*]-(b)-[:RED]->(findme)<-[:RED]-(c)-[*]-(x)
WHERE a.name = "a" AND x.name = "x"
RETURN findme

到三个节点的路径

(a)-[:RED]->(findme)<-[:RED]-(x)

路径中的两个关系可能已被查询的非变量部分匹配。但是没有任何关系可供可变部分匹配。 (a)-[*]-(b) 和 (c)-[*]-(x) 部分都需要“一个或多个”，但还有零个关系需要匹配。

您可以将* 的含义更改为“零或更多”，方法是将其明确指定为一个范围。这样，当路径中没有关系时，查询的两个变量部分也将匹配。

MATCH (a)-[*0..]-(b)-[:RED]->(findme)<-[:RED]-(c)-[*0..]-(x)
WHERE a.name = "a" AND x.name = "x"
RETURN findme

此查询将匹配仅包含您正在查找的“红色三元组”的路径，以及在三元组的一侧或两侧具有延伸关系的路径。

值得注意的是，具有“零或多个”范围匹配“零情况”的模式将在模式中具有两个标识符，但只有一个节点。因此，该节点绑定到两个标识符。对于上面模式左侧的标识符，当它匹配三节点路径时，说

节点a和节点b通过零深度关系连接

真的是很傻的说法

a和b是同一个节点

您可以查看this console，它在(a {name: "a"}) 和(x {name: "x"}) 之间有一个五节点路径，在(a {name: "a2"}) 和(x {name: "x2"}) 之间有一个三节点路径。相同的模式将匹配这两个路径（只需更改WHERE 子句中name 的值）。您将获得两条路径的五列，因为查询返回五个标识符。在三节点路径的情况下，第一个结果列将与第二个相同，第四个与第五个相同——因为 “节点a 和节点b 以零深度关系连接" 只是表示"a 和b 是同一个节点"。

Answer 2

这个怎么样：

MATCH p=(a {name:"a"})-[*]-(x {name:"x"})
WITH nodes(p) AS nodes
UNWIND nodes AS n
WITH n WHERE exists(()-[:RED]->(n)<-[:RED]-())
RETURN n

1. MATCH 在从 a 到 x 的路径上。
2. 获取路径中的所有节点
3. 对于路径中的每个节点，过滤我们有两个传入 RED 关系的节点

Answer 3

我喜欢有多个答案可以完成这项工作:)

这是我的：

MATCH path=(a {name:"a"})-[*]-(x {name:"x"})
RETURN filter(x in nodes(p) WHERE size((x)<-[:RED]-()) = 2) as n

为威尔和乔纳森+1