Excel VBA 更新图表系列

Question

我有一个将范围复制到某个单元格并将数据源更改为图表的代码。该图表具有组合图表类型，具有堆叠列和xlLineMarker 与最后一个系列（总计）。系列集合的数量根据用户选择（2个或更多）而有所不同。

它可以工作，但有时图表不会像所附图像那样完全更新（显示系列名称为“series1，series2，...”的空图表）。发生这种情况时，右键单击图表并单击选择数据，然后只需选择 series1 以外的任何系列即可更新图表。不刷新或重新分配数据源。只需在数据选择窗口中选择“series2”或其他，然后单击“取消”，我怀疑宏没有完全执行...，

我做错了吗？或者有什么方法可以完全更新图表？

Sub chtupdate()

    Dim rng As Range
    Dim i As Integer
    Dim n As Integer

    Set rng = Range("G37").CurrentRegion

    ActiveSheet.ChartObjects("Chart1").Activate
    With ActiveChart
        .ChartArea.ClearContents
        .SetSourceData Source:=rng, PlotBy:=xlRows

        n = ActiveSheet.ChartObjects(1).Chart.SeriesCollection.Count                
        For i = 1 To n - 1
            .SeriesCollection(i).ChartType = xlColumnStacked
        Next i    

        .SeriesCollection(n).ChartType = xlLineMarkers
    End With

End Sub

Answer 1

试试下面的代码，我添加了ChartObject 和Series 对象变量以获得更简单和“更干净”的代码。另外，为了避免使用ActiveSheet 和ActiveChart - 一种不可靠的方法。

代码

Option Explicit

Sub chtupdate()

Dim MyCht       As ChartObject
Dim Ser         As Series

Dim Rng As Range
Dim i As Long
Dim n As Long

' fully qualify all your Ranges and Cells
With Worksheets("Sheet3") ' <-- replace "Sheet1| with your sheet's name
    Set Rng = .Range("G37").CurrentRegion

    ' set the chart object
    Set MyCht = .ChartObjects("Chart1")
End With

With MyCht
    .Chart.ChartArea.ClearContents
    .Chart.SetSourceData Source:=Rng, PlotBy:=xlRows

    For Each Ser In .Chart.SeriesCollection
        Ser.ChartType = xlColumnStacked
    Next Ser

    ' modify the last one
    Set Ser = .Chart.SeriesCollection(.Chart.SeriesCollection.Count)
    Ser.ChartType = xlLineMarkers
End With

End Sub