获取列表中的所有颜色组合？

Question

我有三种可能的颜色：红色、绿色、蓝色。

我有一个初始列表：[blue, blue, blue, blue]。

我基本上需要创建一个搜索算法来查找给定列表Find（这也是一个包含四种颜色的列表）。这是搜索算法的骨架：

look(Find):- search([red, red, red, red], Find).

search([A,B,C,D], [A,B,C,D]):- do-something(A,B,C,D).

search(Node, Find):-
  successor(Node, Next),
  search(Next, Find).

我的问题是定义successor。我如何才能找到一个我确信我以前没有访问过的继任者，直到我找到一个等于列表 Find 的继任者 - 特别是当我没有在谓词中使用域（{red, blue, green}）时.任何帮助表示赞赏。谢谢！

Answer 1

您可以使用member/2 和maplist/2 轻松生成4 种颜色的所有可能性：

% give me a list of 4 fresh variables
% select a member of [red,blue,green] for each item of L, backtrackably

length(L,4),                                   
maplist([I]>>(member(I,[red,blue,green])),L).  

上面其实是一样的

L=[L0,L1,L2,L3],
member(L0,[red,blue,green]),
member(L1,[red,blue,green]),
member(L2,[red,blue,green]),
member(L3,[red,blue,green]).

注意组合爆炸。

如果首选“无状态下一个”。

我们想从现有的组合中推导出下一个红-绿-蓝组合！

让我们使用 CLP(FD) 来实现颜色列表和数字之间的双射映射。

:- use_module(library(clpfd)).

rgbnumber(red,0).
rgbnumber(blue,1).
rgbnumber(green,2).

rgbnumberlist([L0,L1,L2],N) :- 
   rgbnumber(L0,N0), N0 in 0..2,
   rgbnumber(L1,N1), N1 in 0..2,
   rgbnumber(L2,N2), N2 in 0..2,
   N #= N0+N1*3+N2*3*3.

rgbnext(Current,Next,Wrap) :- 
   rgbnumberlist(Current,N),
   succ(N,Nx),
   Nxm is (Nx mod (3*3*3)), % Beware precedence: mod is as strong as *
   (Nx > Nxm -> Wrap = true ; Wrap = false),
   rgbnumberlist(Next,Nxm).

因此：

?- rgbnext([red,red,red],A,Wrap).
A = [blue, red, red],
Wrap = false ;
false.

?- rgbnext([blue,red,red],A,Wrap).
A = [green, red, red],
Wrap = false ;
false.

?- rgbnext([green,red,red],A,Wrap).
A = [red, blue, red],
Wrap = false ;
false.

?- rgbnext([green,green,green],A,Wrap).
A = [red, red, red],
Wrap = true ;
false.

现在您可以使用它从当前状态中查找下一个状态。