使用 clojure 的 core.logic/core.match 解决 Dinesman 的多住宅示例

Question

看完 Sussman 的讲座 http://www.infoq.com/presentations/We-Really-Dont-Know-How-To-Compute，我受到启发，想试试 core.logic 和 core.match。我知道的唯一例子是我小时候做过的那些约束问题解决者。这是一个在 SICP 课程中使用的示例，并且在演讲中被提及：

贝克、库珀、弗莱彻、米勒和史密斯住在一栋只有五层楼的公寓的不同楼层。贝克不住在顶层。库珀不住在底层。弗莱彻既不住在顶层也不住在底层。米勒住在比库珀更高的楼层。史密斯不住在弗莱彻家附近的楼层。弗莱彻不住在库珀附近的楼层。大家都住在哪里？

我在 rosettacode 网站上找到了这个： http://rosettacode.org/wiki/Dinesman%27s_multiple-dwelling_problem#PicoLisp

但不太确定如何将其转化为 clojure。我希望有人可以提供使用 core.logic 或 core.match 解决此问题的示例

Answer 1

这是 core.logic 中的一个解决方案。它不完全等同于 picolisp 算法，因为我们没有可用的相同原语，但它是相同的一般思想。感谢您向我介绍这个问题 - 发明 permuteo 和 beforeo 很有趣，我有第一个借口使用 conda。 编辑：使用conda 是可怕和错误的，我现在回到conde。哦，好吧，总有一天。

(ns dwelling.core
  (:refer-clojure :exclude [==])
  (:use clojure.core.logic))

(defn rembero [x l out]
  (fresh [head tail]
    (conso head tail l)
    (conde [(== x head) (== out tail)]
           [(fresh [new-out]
              (conso head new-out out)
              (rembero x tail new-out))])))

(defn permuteo [a b]
  (conde [(emptyo a) (emptyo b)]
         [(fresh [head tail b-tail]
            (conso head tail a)
            (rembero head b b-tail)
            (permuteo tail b-tail))]))

(defn beforeo [x y l]
  (fresh [head tail]
    (conso head tail l)
    (conde [(== x head) (fresh [more-tail]
                          (rembero y tail more-tail))]
           [(beforeo x y tail)])))

(defn not-adjacento [x y l]
  (fresh [head tail more]
    (conso head tail l)
    (resto tail more)
    (conde [(== x head) (membero y more)]
           [(== y head) (membero x more)]
           [(not-adjacento x y tail)])))

(run* [tenants]
  (fresh [a b c d e]
    (== [a b c d e] tenants)
    (permuteo tenants '[Cooper Baker Fletcher Miller Smith])
    (!= e 'Baker)
    (!= a 'Cooper)
    (!= a 'Fletcher)
    (!= e 'Fletcher)
    (beforeo 'Cooper 'Miller tenants)
    (not-adjacento 'Smith 'Fletcher tenants)
    (not-adjacento 'Fletcher 'Cooper tenants)))

;; ([Smith Cooper Baker Fletcher Miller])

Answer 2

我自己刚刚开始接触 LP，我的第一个尝试是 https://github.com/amalloy/doors，它是 http://rooms.jmpup.com 上自动生成的逻辑谜题的求解器。现在我定义了一些对所有谜题普遍有用的关系，但我还没有做任何工作以编程方式将特定谜题实际翻译成 core.logic。你可以看到我手动翻译的一个谜题——webpage presentation 和core.logic encoding。也许这会让你对如何使用 core.logic 有所了解，虽然我自己还是新手，所以肯定会有不完善的地方。

编辑

查看 picolisp 解决方案后，我认为它不会直接转换为 core.logic，因为据我所知，尚不存在直接否定支持。