如何使用replicateM解决八皇后问题？

Question

我刚开始学习编写 Haskell 代码，如果这是一个愚蠢的问题，我深表歉意。我试图通过使用[] monad 来重做八皇后问题。这是代码，

import Control.Monad

addqueen :: [Int] -> [[Int]]
addqueen xs = [ x:xs | x <- [1,2..8], 
    not $ x `elem` xs 
        || (any (\ (index,q) -> abs (x-q) == index) $ zip [1..] xs) ]

当我尝试时

[[]] >>= replicateM 8 addqueen

它不起作用，但会产生以下错误：

Couldn't match expected type `t0 -> t1' with actual type `[[a0]]'
The first argument of ($) takes one argument,
but its type `[[a0]]' has none
In the expression: [[]] >>= replicateM 8 $ addqueen
In an equation for `it': it = [[]] >>= replicateM 8 $ addqueen

那么我如何在这里实现我想要做的呢？

Answer 1

replicateM 在这里是错误的选择：

Prelude Control.Monad> :t replicateM
replicateM :: (Monad m) => Int -> m a -> m [a]

Prelude Control.Monad> :t addqueen
addqueen :: [Int] -> [[Int]]

这意味着在表达式replicateM 8 addqueen，addqueen的类型与m a匹配，得到m a ~ ([Int] -> [[Int]])，即m ~ ((->) [Int])和a ~ [[Int]]。因此replicateM 8 addqueen 的类型是m [a] ~ ([Int] -> [[[Int]]])。这不是你想要的。

（如果您收到类型错误“没有(Monad ((->) [Int])) 的实例”，请先尝试加载例如Control.Applicative，以引入instance Monad ((->) r) 的定义。如果您'重新使用旧版本的 GHC）。

试试这个吧：

Prelude> :m +Control.Monad

Prelude Control.Monad> :t (>=>)
(>=>) :: (Monad m) => (a -> m b) -> (b -> m c) -> a -> m c

Prelude Control.Monad> :t foldl1 (>=>) $ replicate 8 addqueen
foldl1 (>=>) $ replicate 8 addqueen :: [Int] -> [[Int]]

Prelude Control.Monad> :t [[]] >>= ( foldl1 (>=>) $ replicate 8 addqueen )
[[]] >>= ( foldl1 (>=>) $ replicate 8 addqueen ) :: [[Int]]

---

更新： 表达式 g = foldl1 (>=>) $ replicate 8 addqueen 有其自身的含义。在 Prolog 术语中，它是 a "goal" 在初始解决方案中添加 8 个皇后。我们使用 g，给它一个最初为空的解决方案[ [] ] >>= g。

( 这使用了一个稍微高于基本级别的运算符“fish”¹，即left-to-right Kleisli composition operator >=>，这样定义

(m >>= a) >>= b  ===  m >>= (a >=> b)

即>=> 是一元函数的组合运算符。 )

给你的表达式in the comments by Sassa NF，foldl (>>=) [[]] $ replicate 8 addqueen，使用基本的monadic bind operator >>=，但只能作为一个整体起作用。

¹http://haskellrescue.blogspot.com/2011/03/cooking-delicious-fish.html

Answer 2

你错过了空格

addqueen xs = [x:xs|x<-[1,2..8], not $ x `elem` xs 
    || (any (\(index,q) -> abs (x-q) ==index) $ zip [1..] xs)]

第二，不要同时使用多个中缀函数

--this code is invalid:
[[]] >>= replicateM 8 $ addqueen -- read as [[]] >>= (replicateM 8 $) addqueen

原因是：infixl 1 >>=和infixr 0 $

第三，如果您使用 GHCi，请为“空”数据编写签名。

>([[]] :: [[Int]])>>= replicateM 8 addqueen

您的代码有效

> [[]]>>= replicateM 8 addqueen
[[[1],[2],[3],[4],[5],[6],[7],[8]],[[1],[2],[3],[4],[5],[6],[7],[8]],[[1],[2],[3],[4],[5],[6],[7],[8]],[[1],[2],[3],[4],[5],[6],[7],[8]],[[1],[2],[3],[4],[5],[6],[7],[8]],[[1],[2],[3],[4],[5],[6],[7],[8]],[[1],[2],[3],[4],[5],[6],[7],[8]],[[1],[2],[3],[4],[5],[6],[7],[8]]]