强制 Prolog 选择变量的唯一值

Question

好的，我是 Prolog 的新手，如果这是微不足道的事情，请原谅，但我似乎找不到合适的优雅答案。我正在尝试在learnprolognow.org 上进行练习，练习 2.4（填字游戏）。

该练习提供了以下事实：

   word(astante,  a,s,t,a,n,t,e). 
   word(astoria,  a,s,t,o,r,i,a). 
   word(baratto,  b,a,r,a,t,t,o). 
   word(cobalto,  c,o,b,a,l,t,o). 
   word(pistola,  p,i,s,t,o,l,a). 
   word(statale,  s,t,a,t,a,l,e).

而我想出的解决每个单词的填字游戏位置的解决方案是这样的：

crossword(V1, V2, V3, H1, H2, H3) :-
   word(V1, V1a, V1bH1b, V1c, V1dH2b, V1e, V1fH3b, V1g), 
   word(V2, V2a, V2bH1d, V2c, V2dH2d, V2e, V2fH3d, V2g), 
   word(V3, V3a, V3bH1f, V3c, V3dH2f, V3e, V3fH3f, V3g), 
   word(H1, H1a, V1bH1b, H1c, V2bH1d, H1e, V3bH1f, H1g), 
   word(H2, H2a, V1dH2b, H2c, V2dH2d, H2e, V3dH2f, H2g), 
   word(H3, H3a, V1fH3b, H3c, V2fH3d, H3e, V3fH3f, H3g).

V1a 到 V1g 等是每个单词的字符，V1bH1b 到 V3fH3f 是填字游戏中单词之间的共同字符。

该解决方案似乎有效，但结果是产生重复值，第一个结果是：

?- crossword(V1, V2, V3, H1, H2, H3).
V1 = astante,
V2 = baratto,
V3 = statale,
H1 = astante,
H2 = baratto,
H3 = statale .

如何强制 Prolog 拥有 V1 \= V2 \= V3 \= H1 \= H2 \= H3 ？ 如果我一个一个地做，我需要 120 个排列，所以必须有一个更快的方法，而且这是一个初学者练习，所以我一定会遗漏一些东西。

我找到了this similar question，但是提供的答案似乎很复杂，希望有更简单的方法。我在 Ubuntu 上使用 swi-prolog，以防万一。

谢谢。

Answer 1

使用alldif/1 定义如下：

alldif([]).
alldif([E|Es]) :-
   maplist(dif(E), Es),
   alldif(Es).

这甚至可以用于最一般的查询：

?- alldif(Es).
Es = [] ;
Es = [_G1924] ;
Es = [_G2061, _G2064],
dif(_G2061, _G2064) ;
Es = [_G2163, _G2166, _G2169],
dif(_G2163, _G2169),
dif(_G2163, _G2166),
dif(_G2166, _G2169) ;
Es = [_G2309, _G2312, _G2315, _G2318],
dif(_G2309, _G2318),
dif(_G2309, _G2315),
dif(_G2309, _G2312),
dif(_G2315, _G2318),
dif(_G2312, _G2315),
dif(_G2312, _G2318) ...

目标maplist(dif(E),Es)的含义最好通过查看答案来理解：

?- maplist(dif(E),Es).
Es = [] ;
Es = [_G1987],
dif(E, _G1987) ;
Es = [_G2040, _G2043],
dif(E, _G2043),
dif(E, _G2040) ;
Es = [_G2093, _G2096, _G2099],
dif(E, _G2099),
dif(E, _G2096),
dif(E, _G2093) ;
Es = [_G2146, _G2149, _G2152, _G2155],
dif(E, _G2155),
dif(E, _G2152),
dif(E, _G2149),
dif(E, _G2146) ...

也就是说，Es 是与E 完全不同的元素列表。目标maplist(dif(E),[A,B,C]) 将第一个元素（在本例中为dif(E)）与列表的每个元素相结合。因此dif(E,A), dif(E,B), dif(E,C)。

Answer 2

length(List, N)：N是列表的长度
sort(List, SortedList)：SortedList是List的排序版本（重复元素被删除）

另一方面，拥有可用单词列表并在使用时删除它可能会更快；不仅您不必在最后进行检查，而且您将避免无意义的实例化（A1 = foo, A2 = foo 将立即停止，而不是在最后被拒绝）。换句话说，分支修剪。

Answer 3

@false 在 cmets 中告诉你什么；或者我喜欢用domain selection:

selectM([A|As],S,Z):- select(A,S,S1),selectM(As,S1,Z).
selectM([],Z,Z).

word(astante,  [a,s,t,a,n,t,e]). 
word(astoria,  [a,s,t,o,r,i,a]). 
word(baratto,  [b,a,r,a,t,t,o]). 
word(cobalto,  [c,o,b,a,l,t,o]). 
word(pistola,  [p,i,s,t,o,l,a]). 
word(statale,  [s,t,a,t,a,l,e]).

crossword(Words) :- findall(W, word(_,W), WS),
   Words = [[ _,A,_,B,_,C,_], 
            [ _,D,_,E,_,F,_], 
            [ _,G,_,H,_,I,_],
            [ _,A,_,D,_,G,_],
            [ _,B,_,E,_,H,_],
            [ _,C,_,F,_,I,_]],
   selectM( Words, WS, _).