使用元素插入的 Prolog 置换谓词

Question

我正在尝试编写一个谓词permutation/2，这样当且仅当两个参数都是列表时，它才是真的，一个是另一个的排列。为此，我编写了两个辅助谓词delete/3 和insert/3。当且仅当第三个参数是第二个参数时，第一个为真，两个列表都删除了第一个参数中元素的第一个实例。当且仅当第三个参数等于插入了第一个参数（元素）的第二个参数时，第二个才是真的。

delete(X,[X|T],T). % Base case, element equals head.
delete(X,[A|B],[A|C]) :- delete(X,B,C). % Else, repeat for the tail.

insert(X,[],[X]). % Base case.
insert(X,[H|T],B) :- delete(H,B,U), insert(X,T,U). % Delete all elements from B.

permutation([],[]). % Base case.
permutation([H|T],P) :- permutation(Q,T), insert(H,Q,P). % P a permutation of T, H inserted.

我的想法是查询

?- insert(A,B,X). 

对于给定的 A，B 应该返回所有实例化 X 的方式，使其等于列表 B，其中添加了元素 A。但是，它不会这样做：

?- insert(3,[1,2],X).
X = [1, 2, 3] ;
X = [1, 3, 2] ;
ERROR: Out of global stack

我认为这是因为我定义谓词的方式，检查第三个参数中的列表减去第二个参数中列表的每个元素是否等于仅包含第一个参数的列表，而不是建设性地定义它，但是我很难以另一种方式解决这个问题。然后，排列谓词应检查其第二个参数中的列表是否是递归排列，方法是检查 P 是否是第一个列表的尾部的排列，其中头部随机插入。感谢您的帮助！

Answer 1

insert/3 和 delete/3 都是同一个谓词，在教科书中可以找到 select/3。它也在标准库中，例如在 SWI-Prolog 中，您可以找到它为select/3。您可以使用它来插入或删除，只需根据需要更改列表的位置即可。

从“abc”中删除“b”：

?- select(b, [a,b,c], X).
X = [a, c] ;
false.

在“ac”中任意位置插入“b”：

?- select(b, X, [a,c]).
X = [b, a, c] ;
X = [a, b, c] ;
X = [a, c, b] ;
false.

它的定义与您对delete/3 的定义完全相同，如果您在开源的 SWI-Prolog 中看到 lists.pl 的源代码，您就会看到它。

select(X, [X|Tail], Tail).
select(Elem, [Head|Tail], [Head|Rest]) :-
    select(Elem, Tail, Rest).

但是现在您可以像您描述的那样定义排列。因为我在同一个源文件lists.pl中也找到了这个，所以我只是将源代码复制到这里，因为它是开源的，所以没关系：

perm([], []).
perm(List, [First|Perm]) :-
    select(First, List, Rest),
    perm(Rest, Perm).

我使用lists:perm，因为它是“私有的”，但它不是私有的，只是没有导出：

?- lists:perm([a,b,c], P).
P = [a, b, c] ;
P = [a, c, b] ;
P = [b, a, c] ;
P = [b, c, a] ;
P = [c, a, b] ;
P = [c, b, a] ;
false.

?- lists:perm([a,b,c], [b,a,c]).
true ;
false.

我只有一条信息，那就是：阅读教科书并阅读源代码，因为它可以帮助您更快地学习。