如何以编程方式将文件夹添加到用户的收藏夹（在 Windows 资源管理器中）？

Question

我正在寻找一种以编程方式将文件夹添加到 Windows 资源管理器中的收藏夹的方法。它的 Windows Explorer 特定并基于这个项目：http://www.codeproject.com/Tips/132804/Open-folders-using-a-Run-Command

到目前为止，我已经尝试过 Process Monitor 并搜索注册表，但我似乎无法在 regedit 中找到我的 Windows Explorer 收藏夹。

---

Microsoft 在 Windows 8 中对此进行了更改，因此我相应地标记了我的问题。有关 Win8 等详细信息，请参阅标记答案中的 cmets。

Answer 1

您可以执行以下操作，而不是读取注册表：

string favoritesFolder = 
    Environment.GetFolderPath(Environment.SpecialFolder.Favorites);

Answer 2

P.S.：请务必查看@bsegraves' solution，我认为这比我的要好得多。

我不确定这是否是您要查找的内容，但我认为可以通过以下注册表值找到最喜欢的文件夹：

HKEY_CURRENT_USER\
  Software\
    Microsoft\
      Windows\
        CurrentVersion\
          Explorer\
            User Shell Folders\
              Favorites

您应该能够使用以下代码检索此文件夹名称：

using Microsoft.Win32;
...

RegistryKey topLevel = Registry.CurrentUser;
RegistryKey key = topLevel.OpenSubKey(
    @"Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders",
    true);

string favoriteFolder = key.GetValue("Favorites").ToString();

然后只需在指定文件夹中创建链接或文档即可。

（请注意，此键的值可能类似于%USERPROFILE%\Favorites；环境变量应由上面调用的.GetValue(..) 方法自动扩展。）

Answer 3

对于 Windows 8，此位置已更改为 %USERPROFILE%\Links。请参考this answer。

Answer 4

从 Vista 开始 FOLDERID_Links 添加了常量。它指向 Windows 资源管理器的收藏夹。我的代码（Delphi，但主要思想可见）：

procedure AddFileObjectToFavorites(AParent: HWND; const AObjectFileName: UnicodeString);

  function GetFavorites: PItemIDList;
  begin
    if IsWindowsVistaOrLater then
      OleCheck(SHGetKnownFolderIDList(FOLDERID_Links, 0, 0, Result))
    else
      OleCheck(SHGetFolderLocation(AParent, CSIDL_FAVORITES, 0, 0, Result));
  end;

var
  Desktop: IShellFolder;
  Eaten: DWORD;
  Attr: DWORD;
  ObjectIDList: PItemIDList;
  ObjectParentFolder: IShellFolder;
  ObjectChildIDList: PItemIDList;
  LinksIDList: PItemIDList;
  LinksParentFolder: IShellFolder;
  LinksChildIDList: PItemIDList;
  DataObject: IDataObject;
  LinksDropTarget: IDropTarget;
  Effect: Integer;
begin
  OleCheck(SHGetDesktopFolder(Desktop));
  try
    Attr := 0;
    OleCheck(Desktop.ParseDisplayName(AParent, nil, PWideChar(AObjectFileName), Eaten, ObjectIDList, Attr));
    try
      SHBindToParent(ObjectIDList, IShellFolder, Pointer(ObjectParentFolder), ObjectChildIDList);
      try
        LinksIDList := GetFavorites;
        try
          OleCheck(SHBindToParent(LinksIDList, IShellFolder, Pointer(LinksParentFolder), LinksChildIDList));
          try
            OleCheck(LinksParentFolder.GetUIObjectOf(AParent, 1, LinksChildIDList, IDropTarget, nil, LinksDropTarget));
            try
              OleCheck(ObjectParentFolder.GetUIObjectOf(AParent, 1, ObjectChildIDList, IDataObject, nil, DataObject));
              try
                Effect := DROPEFFECT_LINK;
                OleCheck(LinksDropTarget.DragEnter(DataObject, 0, Point(0, 0), Effect));
                if Effect and DROPEFFECT_LINK = 0 then
                  begin
                    OleCheck(LinksDropTarget.DragLeave);
                    raise Exception.Create('Cannot drop');
                  end;
                Effect := DROPEFFECT_LINK;
                OleCheck(LinksDropTarget.Drop(DataObject, 0, Point(0, 0), Effect));
              finally
                DataObject := nil;
              end;
            finally
              LinksDropTarget := nil;
            end;
          finally
            LinksParentFolder := nil;
          end;
        finally
          CoTaskMemFree(LinksIDList);
        end;
      finally
        ObjectParentFolder := nil;
      end;
    finally
      CoTaskMemFree(ObjectIDList);
    end;
  finally
    Desktop := nil;
  end;
end;