去饱和效果不允许我设置自定义颜色

Question

我对如何创建着色器知之甚少，因此我对如何制作去饱和效果进行了一些研究，并为此借用了着色器代码。我现在遇到的一个问题是，当我尝试设置自定义颜色时，它似乎忽略了我给出的任何值。我想画一些完全黑色的东西，但 Color.Black 和 new Color(0, 0, 0, screen.SATURATION) 没有用。事实上，无论我输入什么 RGB 值，它看起来都是一样的。

这是着色器的代码：

sampler TextureSampler : register(s0);

float4 main(float4 color : COLOR0, float2 texCoord : TEXCOORD0) : COLOR0
{
    // Look up the texture color.
    float4 tex = tex2D(TextureSampler, texCoord);

    // Convert it to greyscale. The constants 0.3, 0.59, and 0.11 are because
    // the human eye is more sensitive to green light, and less to blue.
    float greyscale = dot(tex.rgb, float3(0.3, 0.59, 0.11));

    // The input color alpha controls saturation level.
    tex.rgb = lerp(greyscale, tex.rgb, color.a * 4);

    return tex;
}


technique Desaturate
{
    pass Pass1
    {
        PixelShader = compile ps_2_0 main();
    }
}

我的开始是这样的：

ScreenManager.SpriteBatch.Begin(SpriteSortMode.Immediate, BlendState.AlphaBlend, null, null, null, desaturateEffect, Resolution.getTransformationMatrix() * cam.get_transformation(graphics.GraphicsDevice));

着色器的另一个副作用是，当我通过color * float 淡出某些东西时，它似乎也会去饱和。我有点理解，因为颜色的第三个变量是 a: alpha，这是我放置去饱和变量以发挥其效果的位置。也许有人可以帮助我了解这里发生了什么，也许我可以做些什么来重新获得修改颜色的能力以及保持对饱和度的动态控制。

Answer 1

当您在SpriteBatch.Draw() 中指定颜色值时，它会以COLOR0 语义传递给输入参数。也就是说，这里：

float4 main(float4 color : COLOR0, float2 texCoord : TEXCOORD0) : COLOR0

float4 color 参数将被赋予您通过SpriteBatch.Draw() 传入的值，因为它被标记为COLOR0。

除了输出着色纹理颜色之外什么都不做的沼泽标准像素着色器如下所示：

float4 main(float4 color : COLOR0, float2 texCoord : TEXCOORD0) : COLOR0
{
    return tex2D(TextureSampler, texCoord) * color;
}

注意乘以color。这将纹理的 R 乘以颜色的 R，将纹理的 G 乘以颜色的 G，以此类推，通过 B 和 A，为纹理提供的原始颜色着色。

所以你可能想要做的是：

float4 main(float4 color : COLOR0, float2 texCoord : TEXCOORD0) : COLOR0
{
    // Look up the texture color.
    float4 tex = tex2D(TextureSampler, texCoord);
    tex.rgb *= color.rgb;

    // Convert it to greyscale. The constants 0.3, 0.59, and 0.11 are because
    // the human eye is more sensitive to green light, and less to blue.
    float greyscale = dot(tex.rgb, float3(0.3, 0.59, 0.11));

    // The input color alpha controls saturation level.
    tex.rgb = lerp(greyscale, tex.rgb, color.a * 4);

    return tex;
}

这将在计算灰度值或执行 lerp 之前对原始纹理颜色进行着色 - 但仅对 RGB 通道进行着色。