项目后面的 QML 着色器效果模糊

Question

是否可以模糊另一个项目后面的项目？

示例：模糊图像的一部分（如 qml - parent.centerIn: image）

我想要类似的东西：

Image { id: img
    anchors.fill: parent
    source: "bug.png"

    Item { id: info
        anchors.centerIn: parent
        height: 200
        width: 200

        Text {
            text: "HAMMER TIME"
            color: "white"
        }

        /* BLUR CODE HERE TO BLUR BACKGROUND OF THIS ITEM */
        /* which is a part of "bug.png" image with 200x200 size */
        /* and offset equals to "info.x" and "info.y" */
    }
}

这个问题会影响任何shader effect，因为官方文档没有这个问题的答案，而且我的所有尝试都没有成功 - 只能模糊整个项目，但不能模糊它的一部分。

Answer 1

这是我的解决方案。此版本仅适用于矩形。 Item ShaderEffectSource 有助于创建这样的源矩形。

import QtQuick 2.3
import QtQuick.Window 2.2
import QtGraphicalEffects 1.0

Window {
    visible: true
    width: 600
    height:600

    Image {
        id: image_bug

        anchors.fill: parent
        source: "images/Original_bug.png"
    }

    ShaderEffectSource {
        id: effectSource

        sourceItem: image_bug
        anchors.centerIn: image_bug
        width: 400
        height: 400
        sourceRect: Qt.rect(x,y, width, height)
    }

    FastBlur{
        id: blur
        anchors.fill: effectSource

        source: effectSource
        radius: 100
    }
}

如果您需要其他形状，我认为您可能需要应用蒙版着色器，先切出相关部分，然后再应用模糊。

Answer 2

不是最漂亮的解决方案，但恐怕没有这样的 Qml 机制。
您可以将具有相同来源的第二张图片应用到您的图片上，然后根据您的需要进行剪辑，如下所示：

Image {
    id: img
    anchors.fill: parent
    source: "bug.png"

    Item { id: info
        anchors.centerIn: parent
        height: 200
        width: 200

    Text {
        text: "HAMMER TIME"
        color: "white"
    }

    /* BLUR CODE HERE TO BLUR BACKGROUND OF THIS ITEM */
    /* which is a part of "bug.png" image with 200x200 size */
    /* and offset equals to "info.x" and "info.y" */

    clip:true
    Image {
        id: img2
        x: -info.x
        y: -info.y
        width: img.width
        height: img.height
        source: img.source
    }
    FastBlur {
        anchors.fill: img2
        source: img2
        radius: 32
    }
}