Grails设置3个类的映射表

Question

我是 grails 的新手。我有 3 个类如下

class Cycle 
{
    int year
    int quarter
}

class User
{
    String username, password           
}           

class Role
{
    String roleName 
} 

User 和 Role 表是独立的，它们分别存储所有员工和可用角色的详细信息。 员工在每个周期中可以担任多个角色。所以我想要一个像

这样的映射表

查找在特定周期中属于员工的所有角色。 我如何在这些类之间设置适当的关系来解决这种情况，以便如果我有一个循环和一个用户，我可以找出用户在那个循环中的所有角色 此外，如果我有一个用户，我可以找到他参与的所有周期以及他在每个周期中的角色

Answer 1

在评论之后。 您应该在 User 和 Cycle 之间创建一个表

class UserCycle
{
    User user
    Cycle cycle
    static hasMany = [roles: Role]
}

角色类应如下所示：

class Role
{
     String roleName
     UserCycle userCycle
}

在代码中你可以这样引用：

UserCycle uc = ...
def roles = uc.roles.list(params) //list of roles
def cycle = uc.cycle
def user = uc.user

添加

uc.addToRoles(/*Your role*/)

删除

uc.removeFromRoles(/*Your role*/)

Answer 2

您需要添加一个连接表（域类），用于存储特定周期中用户和角色之间的映射。这是一个此类的示例，其中包含一些可能有用的辅助方法

class UserRole implements Serializable {

    User user
    Role role
    Cycle cycle

    static UserRole create(User user, Role role, Cycle cycle, boolean flush = false) {
        new UserRole(user: user, role: role, cycle: cycle).save(flush: flush, insert: true)
    }

    static boolean remove(User user, Role role, Cycle cycle, boolean flush = false) {
        UserRole instance = UserRole.findByUserAndRoleAndCycle(user, role, cycle)
        if (!instance) {
            return false
        }

        instance.delete(flush: flush)
        true
    }

    static void removeAll(User user) {
        executeUpdate 'DELETE FROM UserRole WHERE user=:user', [user: user]
    }

    static void removeAll(Role role) {
        executeUpdate 'DELETE FROM UserRole WHERE role=:role', [role: role]
    }

    static void removeAll(Cycle cycle) {
        executeUpdate 'DELETE FROM UserRole WHERE cycle=:cycle', [cycle: cycle]
    }

    static mapping = {
        id composite: ['role', 'user', 'cycle']
        version false
    }
}