键盘钩子过程的问题

Question

背景：我的表单有一个 TWebBrowser。我想用 ESC 关闭表单，但 TWebBrowser 吃掉了击键 - 所以我决定使用键盘挂钩。

问题是Form可以同时在多个实例中打开。

无论我做什么，在某些情况下，如果我的表单打开了两个实例，关闭其中一个实例也会关闭另一个。

我附上了一些示例代码。关于导致问题的任何想法？

var
  EmailDetailsForm: TEmailDetailsForm;
  KeyboardHook: HHook;

implementation

function KeyboardHookProc(Code: Integer; wParam, lParam: LongInt): LongInt; stdcall;
var
  hWnd: THandle;
  I: Integer;
  F: TForm;
begin
  if Code < 0 then
    Result := CallNextHookEx(KeyboardHook, Code, wParam, lParam)
  else begin
    case wParam of
      VK_ESCAPE:  
        if (lParam and $80000000) <> $00000000 then
        begin
          hWnd := GetForegroundWindow;
          for I := 0 to Screen.FormCount - 1 do
          begin
            F := Screen.Forms[I];
            if F.Handle = hWnd then
              if F is TEmailDetailsForm then
              begin
                PostMessage(hWnd, WM_CLOSE, 0, 0);
                Result := HC_SKIP;
                break;
              end;
          end; //for
        end; //if
      else
        Result := CallNextHookEx(KeyboardHook, Code, wParam, lParam);
    end;  //case
  end;  //if
end;

function TEmailDetailsForm.CheckInstance: Boolean;
var
  I, J: Integer;
  F: TForm;
begin
  Result := false;

  J := 0;

  for I := 0 to Screen.FormCount - 1 do
  begin
    F := Screen.Forms[I];
    if F is TEmailDetailsForm then
    begin
      J := J + 1;
      if J = 2 then
      begin
        Result := true;
        break;
      end;
    end;
  end;
end;

procedure TEmailDetailsForm.FormCreate(Sender: TObject);
begin
    if not CheckInstance then    
      KeyboardHook := SetWindowsHookEx(WH_KEYBOARD, @KeyboardHookProc, 0, GetCurrentThreadId());
end;

procedure TEmailDetailsForm.FormDestroy(Sender: TObject);
begin
    if not CheckInstance then
      UnHookWindowsHookEx(KeyboardHook);
end;

Answer 1

您可以改用TApplicationEvents.OnMessage 来执行此操作。使用以下代码将 TApplicationEvents 组件拖放到应用程序的主窗体上：

procedure TMainForm.ApplicationEvents1Message(var Msg: tagMSG;
  var Handled: Boolean);
var
  C: TControl;
  H: HWND;
begin
  if (Msg.message = WM_KEYDOWN) and (Msg.wParam = VK_ESCAPE) then begin
    H := Msg.hwnd;
    while GetParent(H) <> 0 do
      H := GetParent(H);
    C := FindControl(H);
    if C is TEmailDetailsForm then begin
      TEmailDetailsForm(C).Close;
      Handled := True;
    end;
  end;
end;

如果您想继续使用键盘挂钩，您应该只挂钩一次，而不是每个表单一次，特别是因为您要覆盖全局变量。尝试添加一个 HookCount 全局变量，如果它是唯一的形式，则仅挂钩/取消挂钩。

Answer 2

背景：我的表单有一个 TWeb浏览器。我想关闭表格 使用 ESC 但 TWebBrowser 吃掉了 击键 - 所以我决定使用 键盘挂钩。

可能有一个更简单的解决方案。您是否尝试过将表单的KeyPreview 属性设置为True？

Answer 3

嗯，这两个表单都已注册以接收键盘通知，因此它们都关闭了。 您需要在其中输入代码来决定“这个 ESC 适合我吗？”。也许通过确定您是否是焦点窗口。如果不是您的 ESCape，请不要关闭。

但是，这一切似乎都相当激烈。必须有一种更简单、不显眼的方法来检测此 APP 中的 ESC，而无需监控整个系统的键盘。