如何与 TWebBrowser 控件中的 TAutoIntfObject 对象进行互操作？

Question

我有一个TWebBrowser 控件，它实现IDocHostUIHandler 以通过IDispatch 容器扩展对JavaScript 互操作的控制。这工作正常，除了我不知道如何将事件从 JavaScript 分派回 Web 浏览器控件。

扩展对象是一个基于TAutoIntfObject 的容器，类似于this example。正如您在示例中看到的，与 Web 浏览器控件没有互操作性。理想情况下，我想在该扩展对象上实现事件，但我不知道如何在我的 Web 浏览器控件中正确声明 TAutoIntfObject 对象。假设我有这个扩展对象：

type
  TZoomChangeEvent = procedure(Sender: TObject; ZoomLevel: Integer) of object;
  TOpenLayersExt = class(TAutoIntfObject, IOpenLayers)
  private
    FOnZoomChange: TZoomChangeEvent;
    // the ZoomChange method is invoked from JavaScript
    procedure ZoomChange(ZoomLevel: Integer); safecall;
  public
    property OnZoomChange: TZoomChangeEvent read FOnZoomChange write FOnZoomChange;
  end;

implementation

procedure TOpenLayersExt.ZoomChange(ZoomLevel: Integer);
begin
  if Assigned(FOnZoomChange) then
    FOnZoomChange(Self, ZoomLevel);
end;

还有一个像这样的TWebBrowser 控件：

type
  TMapBrowser = class(TWebBrowser, IDocHostUIHandler)
  private
    // the extension object
    FExtObj: TOpenLayersExt;
    // IDocHostUIHandler::GetExternal method
    function GetExternal(out ppDispatch: IDispatch): HRESULT; stdcall;
    // this is the TOpenLayersExt.OnZoomChange event method implementation
    procedure OnZoomChange(Sender: TObject; Zoom: Integer);
  public
    // ordinary constructor
    constructor Create(AOwner: TComponent); override;
  end;

implementation

constructor TMapBrowser.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  // create extension object
  FExtObj := TOpenLayersExt.Create;
  // here the event method is properly binded; if I'd change the FExtObj type
  // to IDispatch with TOpenLayersExt(FExtObj) typecast, it wouldn't
  FExtObj.OnZoomChange := OnZoomChange;
end;

function TMapBrowser.GetExternal(out ppDispatch: IDispatch): HRESULT;
begin
  // the problem is that I don't know how to properly pass this object to the
  // ppDispatch parameter; if this GetExternal method is called second time,
  // the FExtObj seems to be released, but I don't get why
  ppDispatch := FExtObj as IDispatch;
  Result := S_OK;
end;

问题在于，如果我将FExtObj 对象声明为TOpenLayersExt，则事件方法已绑定，但FExtObj 对象引用似乎在第一个扩展对象方法调用（来自JavaScript）之后被释放。

如果我声明为IDispatch，则在JavaScript函数调用后不会释放引用，但OnZoomChange事件没有绑定。

这里很难发布完整的代码，因为它由更多部分组成，here is a complete project 在 Delphi 7 中制作。

所以我的问题是，如何在 Web 浏览器控件中使用来自 TAutoIntfObject 扩展对象的事件；如何声明扩展对象，以便我能够处理来自 Web 浏览器控件的事件并将其传递给 IDocHostUIHandler::GetExternal 方法参数仍然保持接口对象引用？

Answer 1

使用引用计数，即。将 FExtObj 保留为对接口的引用，而不是对象：

  private
    // the extension object
    FExtObj: IDispatch;

...

constructor TMapBrowser.Create(AOwner: TComponent);
var
  AExtObj: TOpenLayersExt;
begin
  inherited Create(AOwner);
  // create extension object
  AExtObj := TOpenLayersExt.Create;
  AExtObj.OnZoomChange := OnZoomChange;
  FExtObj := AExtObj as IDispatch;
end;

destructor TMapBrowser.Destroy;
begin
  FExtObj := nil;
  inherited Destroy;
end;