为什么我的 OpenGL 自定义着色器给我这个错误？

Question

我在 XCode11 上为我的 macOS 应用程序使用带有 cocos2d 3.17 的自定义着色器，但我遇到了一些问题。

myShader.frag

#ifdef GL_ES
 precision lowp float;
#endif

uniform sampler2D u_texture;
varying lowp vec4 v_fragmentColor;
uniform mat4 u_rotation;

void main()
{
  mat4 t1= mat4(1);
  mat4 t2= mat4(1);
  t1[3] = vec4(-0.5,-0.5,1,1);
  t2[3] = vec4(+0.5,+0.5,1,1);
  vec2 pos = (t2 * u_rotation * t1 * vec4(gl_PointCoord, 0, 1)).xy;
  gl_FragColor  =  v_fragmentColor * texture2D(u_texture, pos);
}

myShader.vert

attribute vec4 a_position;
uniform float u_pointSize;
uniform lowp vec4 u_fragmentColor;
varying lowp vec4 v_fragmentColor;

void main()
{
  gl_Position     = CC_MVPMatrix * a_position;
  gl_PointSize    = u_pointSize;
  v_fragmentColor = u_fragmentColor;
}

使用这个配置我有这个错误：

cocos2d: ERROR: 0:21: 'vec4' : 语法错误：语法错误

关于 myShader.vert

我不明白，我觉得很好。

Answer 1

着色器是为OpenGL ES (GLSL ES 1.00) 编写的。当您尝试使用 "desktop" OpenGL 编译着色器时，由于精度限定符，您会遇到错误。

删除顶点着色器中的精度限定符：

attribute vec4 a_position;
uniform float u_pointSize;
uniform vec4 u_fragmentColor;
varying vec4 v_fragmentColor;

void main()
{
  gl_Position     = CC_MVPMatrix * a_position;
  gl_PointSize    = u_pointSize;
  v_fragmentColor = u_fragmentColor;
}

和片段着色器：

#ifdef GL_ES
 precision lowp float;
#endif

uniform sampler2D u_texture;
varying vec4 v_fragmentColor;
uniform mat4 u_rotation;

// [...]

在 GLSL 1.30 (OpenGL 3.0) 代码可移植性（不是为了功能）中添加了精确限定符，但之前的版本不支持它们。
（由于您没有指定版本，因此您使用的是 GLSL 1.00）

---

或者，您可以使用宏作为精度限定符：

#ifdef GL_ES
#define LOWP lowp 
#else
#define LOWP
#endif

attribute vec4 a_position;
uniform float u_pointSize;
uniform LOWP vec4 u_fragmentColor;
varying LOWP vec4 v_fragmentColor;

// [...]

#ifdef GL_ES
precision lowp float;
#define LOWP lowp 
#else
#define LOWP
#endif

uniform sampler2D u_texture;
varying LOWP vec4 v_fragmentColor;
uniform mat4 u_rotation;

// [...]