如何在 windows 的变量中获取命令的结果？

Question

我希望将命令的结果作为 Windows 批处理脚本中的变量获取（请参阅 how to get the result of a command in bash 以获取等效的 bash 脚本）。首选可以在 .bat 文件中运行的解决方案，但也欢迎使用其他常见的 Windows 脚本解决方案。

Answer 1

不起眼的 for 命令多年来积累了一些有趣的功能：

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

请注意，"delims=" 会覆盖默认的空格和制表符分隔符，因此 date 命令的输出会被一次性全部吞噬。

要捕获多行输出，它本质上仍然可以是单行（使用变量 lf 作为结果变量中的分隔符）：

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

要捕获管道表达式，请使用^|：

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"

Answer 2

如果您必须捕获所有命令输出，您可以使用这样的批处理：

@ECHO OFF
IF NOT "%1"=="" GOTO ADDV
SET VAR=
FOR /F %%I IN ('DIR *.TXT /B /O:D') DO CALL %0 %%I
SET VAR
GOTO END

:ADDV
SET VAR=%VAR%!%1

:END

所有输出行都存储在用“！”分隔的 VAR 中。

但如果只需要单行控制台输出，请尝试：

@ECHO off
@SET MY_VAR=
FOR /F %%I IN ('npm prefix') DO @SET "MY_VAR=%%I"

@REM Do something with MY_VAR variable...

@John：这有什么实际用途吗？我认为您应该观看 PowerShell 或任何其他能够轻松执行脚本任务的编程语言（Python、Perl、PHP、Ruby）

Answer 3

要获取当前目录，可以这样：

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

虽然它使用的是临时文件，所以它不是最漂亮的，但它确实有效！ 'CD' 将当前目录放在 'tmpFile' 中，'SET' 加载 tmpFile 的内容。

这里是多行的“数组”的解决方案：

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

但是您可能想要考虑迁移到另一个更强大的 shell 或为这些东西创建一个应用程序。这大大扩展了批处理文件的可能性。

Answer 4

您需要使用带有参数/P 的SET 命令并将输出定向到它。 例如参见http://www.ss64.com/nt/set.html。适用于 CMD，不确定 .BAT 文件

来自对该帖子的评论：

该链接的命令“Set /P _MyVar=<MyFilename.txt”表示它将设置_MyVar 到第一行 来自MyFilename.txt。这可能是 用作“myCmd > tmp.txt”和“set /P myVar=<tmp.txt”。但它只会 获取输出的第一行，而不是 所有输出

Answer 5

在“V”环境变量中设置最新文件的示例

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

在批处理文件中，您必须在循环变量中使用双前缀：

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I

Answer 6

我想对上述解决方案补充一点：

如果在路径中找到您的命令，或者如果命令是没有空格或特殊字符的 cmdpath，则所有这些语法都可以很好地工作。

但是，如果您尝试使用位于路径包含特殊字符的文件夹中的可执行命令，则需要将命令路径用双引号 (") 括起来，然后 FOR /F 语法不起作用。

例子：

$ for /f "tokens=* USEBACKQ" %f in (
    `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" Hello '"F:\GLW7\Distrib\System\Shells and scripting"'`
) do echo %f
The filename, directory name, or volume label syntax is incorrect.

或

$ for /f "tokens=* USEBACKQ" %f in (
      `"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'F:\GLW7\Distrib\System\Shells' is not recognized as an internal or external command, operable program or batch file.

或

`$ for /f "tokens=* USEBACKQ" %f in (
     `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello' is not recognized as an internal or external command, operable program or batch file.

在这种情况下，我发现使用命令并将其结果存储在变量中的唯一解决方案是将（临时）默认目录设置为命令本身：

pushd "%~d0%~p0"
FOR /F "tokens=* USEBACKQ" %%F IN (
    `FOLDERBROWSE "Hello world!" "F:\GLW7\Distrib\System\Layouts (print,display...)"`
) DO (SET MyFolder=%%F)
popd
echo My selected folder: %MyFolder%

那么结果就是正确的：

My selected folder: F:\GLW7\Distrib\System\OS install, recovery, VM\
Press any key to continue . . .

当然，在上面的示例中，我假设我的批处理脚本与我的可执行命令之一位于同一文件夹中，以便我可以使用“%~d0%~p0”语法。如果这不是您的情况，那么您必须找到一种方法来定位您的命令路径并将默认目录更改为它的路径。

注意：对于那些想知道的人，这里使用的示例命令（选择文件夹）是 FOLDERBROWSE.EXE。我在网站 f2ko.de (http://f2ko.de/en/cmd.php) 上找到了它。

如果有人对通过复杂路径访问的那种命令有更好的解决方案，我会很高兴听到它。

吉尔

Answer 7

只需使用FOR 命令的结果即可。例如（在批处理文件中）：

for /F "delims=" %%I in ('dir /b /a-d /od FILESA*') do (echo %%I)

您可以使用%%I 作为您想要的值。就像这样：%%I。

并且预先%%I没有任何空格或CR字符，可以用来比较！！

Answer 8

如果您正在寻找Using the result of a command as an argument in bash?中提供的解决方案

下面是代码：

@echo off
if not "%1"=="" goto get_basename_pwd
for /f "delims=X" %%i in ('cd') do call %0 %%i
for /f "delims=X" %%i in ('dir /o:d /b') do echo %%i>>%filename%.txt
goto end

:get_basename_pwd
set filename=%~n1

:end

• 这将使用 CD 命令的结果调用自身，与 pwd 相同。
• 对参数的字符串提取将返回文件名/文件夹。
• 获取此文件夹的内容并附加到文件名.txt

[Credits]：感谢所有其他答案以及Windows XP commands 页面上的一些挖掘。

Answer 9

@echo off

ver | find "6.1." > nul
if %ERRORLEVEL% == 0 (
echo Win7
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)

ver | find "5.1." > nul
if %ERRORLEVEL% == 0 (
echo WinXP
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)
echo Outlook dir:  %findoutlook%
"%findoutlook%"

Answer 10

您可以在一个变量中捕获所有输出，但行将由您选择的字符（下例中的#）分隔，而不是实际的 CR-LF。

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
)
echo directory contains:
echo %DIR%

第二版，如果需要逐行打印出来。这得益于“dir /b”不会有重复的输出行，因此它在一般情况下可能不起作用。

@echo off
setlocal EnableDelayedExpansion
set count=0
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
    set /a count = !count! + 1
)

echo directory contains:
echo %DIR%

for /l %%c in (1,1,%count%) do (
    for /f "delims=#" %%i in ("!DIR!") do (
        echo %%i
        set DIR=!DIR:%%i=!
    )
)

Answer 11

@echo off
setlocal EnableDelayedExpansion
FOR /F "tokens=1 delims= " %%i IN ('echo hola') DO (
    set TXT=%%i
)
echo 'TXT: %TXT%'

结果是'TXT: hola'

Answer 12

你应该使用for命令，这里是一个例子：

@echo off
rem Commands go here
exit /b
:output
for /f "tokens=* useback" %%a in (`%~1`) do set "output=%%a"

您可以使用call :output "Command goes here"，然后输出将在%output% 变量中。

注意：如果您有一个多行命令输出，此工具会将set 输出到您的多行命令的最后一行。

Answer 13

请参阅此http://technet.microsoft.com/en-us/library/bb490982.aspx，它解释了您可以使用命令输出做什么。