VB6 中的 CheckTokenMembership - 在 Windows 7 和 Windows 2008 上的 FreeSID 崩溃

Question

我正在使用CheckTokenMembership Windows API 来检查用户是否是管理员。

代码如下：

Option Explicit

Private Const SECURITY_BUILTIN_DOMAIN_RID       As Long = &H20
Private Const DOMAIN_ALIAS_RID_ADMINS           As Long = &H220

Private Declare Function AllocateAndInitializeSid Lib "advapi32.dll" (pIdentifierAuthority As Any, ByVal nSubAuthorityCount As Byte, ByVal nSubAuthority0 As Long, ByVal nSubAuthority1 As Long, ByVal nSubAuthority2 As Long, ByVal nSubAuthority3 As Long, ByVal nSubAuthority4 As Long, ByVal nSubAuthority5 As Long, ByVal nSubAuthority6 As Long, ByVal nSubAuthority7 As Long, lpPSid As Long) As Long
Private Declare Sub FreeSid Lib "advapi32.dll" (ByVal pSid As Long)
Private Declare Function CheckTokenMembership Lib "advapi32.dll" (ByVal hToken As Long, ByVal pSidToCheck As Long, pbIsMember As Long) As Long

Private Type SID_IDENTIFIER_AUTHORITY
    Value(0 To 5)            As Byte
End Type

Private Function pvIsAdmin() As Boolean
    Dim uAuthNt         As SID_IDENTIFIER_AUTHORITY
    Dim pSidAdmins      As Long
    Dim lResult         As Long

    uAuthNt.Value(5) = 5
    If AllocateAndInitializeSid(uAuthNt, 2, SECURITY_BUILTIN_DOMAIN_RID, DOMAIN_ALIAS_RID_ADMINS, 0, 0, 0, 0, 0, 0, pSidAdmins) <> 0 Then
        If CheckTokenMembership(0, pSidAdmins, lResult) <> 0 Then
            pvIsAdmin = (lResult <> 0)
        End If
        Call FreeSid(pSidAdmins)
    End If
End Function

问题是在 Windows 7 和 Windows 2008 SP2 上，对 FreeSID 的调用导致应用程序崩溃。崩溃是间歇性的。

有人遇到过这个问题吗？

谢谢！

编辑：

我刚刚重新检查了我的代码，发现我这样声明了 FreeSID：

Private Declare Sub FreeSid Lib "advapi32.dll" (pSid As Long)

与上面的代码相比，这里的pSid参数没有被标记为ByVal。我添加了 ByVal 标志，问题不再存在。不知何故，我不相信这能解决问题。这可能解决了问题吗？

Answer 1

在一个完全独立的模块中分离pvIsAdmin，并从sn-p 中逐字复制函数声明。在AllocateAndInitializeSid lpPSid 是 ByRef。 FreeSid 中的参数是 ByVal。