Cython 在没有 gil 的情况下迭代 numpy 数组列表

Question

我想遍历具有不同维度的 numpy 数组列表，并将它们传递给不需要 GIL 的 cython 函数：

# a has T1 rows and M columns
a = np.array([[0.0, 0.1, 0.3, 0.7],
              [0.1, 0.2, 0.1, 0.6],
              [0.1, 0.2, 0.1, 0.6]])

# b has T2 rows and M columns
b = np.array([[1.0, 0.0, 0.0, 0.0],
              [0.1, 0.2, 0.1, 0.6]])

# c has T3 rows and M columns
c = np.array([[0.1, 0.0, 0.3, 0.6],
              [0.5, 0.2, 0.3, 0.0],
              [0.0, 1.0, 0.0, 0.0],
              [0.0, 0.0, 0.1, 0.0]])

array_list = [a, b, c]
N = len(array_list)

# this function works
@cython.boundscheck(False)
@cython.wraparound(False)
cdef void function_not_requiring_the_gil(double[:, ::1] arr) nogil:
    cdef int T = arr.shape[0]
    cdef int M = arr.shape[1]
    cdef int i, t

    for t in range(T):
        for i in range(M):
            # do some arbitrary thing to the array in-place
            arr[t, i] += 0.001

# issue is with this function
def function_with_loop_over_arrays(array_list, int N):
    cdef int i

    with nogil:
        for i in range(N):
            function_not_requiring_the_gil(array_list[i])

编译 Cython 代码时，出现以下错误：

Error compiling Cython file:
------------------------------------------------------------
...
def function_with_loop_over_arrays(array_list, int N):
    cdef int i

    with nogil:
        for i in range(N):
            function_not_requiring_the_gil(array_list[i])                                                    ^
------------------------------------------------------------

my_file.pyx:312:53: Indexing Python object not allowed without gil

是否有另一种类型的数据结构可以用来代替 Python 列表来存储这些 numpy 数组，这样我就可以在没有 gil 的情况下遍历它们？我对涉及 malloc C 指针/Cython memoryviews/其他我不知道的类型的建议持开放态度。

请注意，每个 numpy 数组都有不同的行数，但数组列表的长度是已知的。

Answer 1

您可以将两个形状为 (3,) 的数组传递给 function_with_loop_over_arrays：一个 (array_starts) 包含指向 a、b 和 c 的第一个元素的指针，以及一个 (arrays_rows ) 其中包含T1、T2 和T3。

然后修改function_not_requiring_the_gil，使其接收数组第一个元素的指针及其行数，然后您就可以在function_with_loop_over_arrays 中调用它：

for i in range(N):  # N is 3 and should be passed to function_with_loop_over_arrays
    function_not_requiring_the_gil(array_starts[i], array_rows[i])  

Answer 2

正如错误消息所说，没有 gil，您无法索引 Python list，并且实际上没有任何明显的替代数据结构可以充当相同的角色。您只需移动 nogil 即可将索引移出它

def function_with_loop_over_arrays(array_list, int N):
    cdef int i
    cdef double[:, ::1] tmp_mview

    for i in range(N):
        tmp_mview = array_list[i]
        with nogil:        
            function_not_requiring_the_gil(tmp_mview)

（等效地，您可以将索引放在 with gil: 块中。）

获取和发布gil 的成本很小，但只要您的function_not_requiring_the_gil 与索引编制相比，它做了相当多的工作，它应该是微不足道的。

Answer 3

nogil 的功能通常很容易从numba 控制：

import numba
@numba.jit(nogil=True) 
def function_not_requiring_the_gil(arr):
    T,N = arr.shape
    for t in range(T):
        for i in range(N):
        # do some arbitrary thing to the array in-place
        arr[t, i] += 0.001

def function_with_loop_over_arrays(array_list)
        for a in array_list:
            function_not_requiring_the_gil(a)

会给你同样（高效）的结果。