“更改用户”时 CreateProcessAsUser 不起作用

Question

首先，我要感谢所有为本网站工作的人，这对开发人员非常有用。这是我 3 天以来的第一次发展受阻。我在互联网上搜索了解决方案，但没有找到解决此问题的方法。

所以，我开发了一个服务，当用户登录时，它必须在 vista/seven/xp 上执行一个外部程序。该服务的一些特点：

• 自动
• 没有互动。
• 检测登录用户的会话 ID

以交互式用户身份运行外部 GUI 应用程序：

1. 为确保打开用户会话，我列出了所有“explorer.exe”进程，并使用 msdn 函数 ProcessIdToSessionId 提取它们的 Pid 和 SessionID
2. 如果登录用户的 SessionID 与此“explorer.exe”进程的会话 ID 相同，我确信“好的”桌面正在运行，所以现在我可以执行外部程序。 （我说“好”桌面是因为，如您所知，系统上可以打开多个用户会话）

3. 之后，我用这个函数运行应用程序：

   function RunInteractive(prog_filename: String; sessionID: Cardinal): boolean;
   var hToken: THandle;
   si: _STARTUPINFOA;
   pi: _PROCESS_INFORMATION;
   begin
   ZeroMemory(@si, SizeOf(si));
   si.cb := SizeOf(si);
   SI.lpDesktop := nil;
   if WTSQueryUserToken(sessionID, hToken)
   then  begin
         if CreateProcessAsUser(hToken, nil, PChar(prog_filename), nil, nil, False, 0, nil, PChar(ExtractFilePath(prog_filename)), si, pi)
         then  result := true
         else result := false;
       end
   else  Begin
         result := false;
         End;
   CloseHandle(hToken);
   end;
   

此代码在大多数情况下都可以，除了一个：当我更改用户时。让我用 2 个简单的用户（Domain\user1 和 Domain\user2）来解释一下：

1. 为了干净，我安装服务并重新启动系统
2. 我打开与 user1 的会话：外部程序已执行，我可以看到它的形式
3. 我关闭会话并打开与 user2 的会话：外部程序已执行，我可以看到它的表单。

如果我这样做 X 次，结果总是一样的，非常好...但是如果我这样做：

1. 我重新安装服务并重新启动系统
2. 我打开与 user1 的会话：外部程序已执行，我可以看到它的形式
3. 这一次，我没有关闭会话，而是更改用户 with user2 : 外部程序已执行，但我看不到表单并出现错误：系统错误代码 5：访问被拒绝。

出了点问题，但我没有找到解决方案。感谢您的回答...

Answer 1

您不需要枚举正在运行的 explorer.exe 进程，您可以改用 WTSGetActiveConsoleSessionId()，然后将该 SessionId 传递给 WTSQueryUserToken()。请注意，WTSQueryUserToken() 返回一个模拟令牌，但 CreateProcessAsUser() 需要一个主令牌，因此使用 DuplicateTokenEx() 进行该转换。

您还应该使用CreateEnvironmentBlock()，以便生成的进程具有适合正在使用的用户帐户的适当环境。

最后，将 STARTUPINFO.lpDesktop 字段设置为 'WinSta0\Default' 而不是 nil，这样生成的 UI 就可以正确可见。

我已经使用这种方法好几年了，并且没有遇到任何问题。例如：

function CreateEnvironmentBlock(var lpEnvironment: Pointer; hToken: THandle; bInherit: BOOL): BOOL; stdcall; external 'userenv.dll'
function DestroyEnvironmentBlock(lpEnvironment: Pointer): BOOL; stdcall; external 'userenv.dll';

function RunInteractive(prog_filename: String): Boolean;
var
  hUserToken, hToken: THandle;
  si: _STARTUPINFOA;
  pi: _PROCESS_INFORMATION;
  SessionId: DWORD;
  Env: Pointer;
begin
  Result := False;

  ZeroMemory(@si, SizeOf(si));
  si.cb := SizeOf(si);
  si.lpDesktop := 'WinSta0\Default';

  SessionId := WTSGetActiveConsoleSessionId;
  if SessionId = $FFFFFFFF then Exit;

  if not WTSQueryUserToken(SessionID, hToken) then Exit;
  try
    if not DuplicateTokenEx(hToken, MAXIMUM_ALLOWED, nil, SecurityIdentification, TokenPrimary, hUserToken) then Exit;
  finally
    CloseHandle(hToken);
  end;

  try
    if not CreateEnvironmentBlock(Env, hUserToken, False) then Exit;
    try
      Result := CreateProcessAsUser(hUserToken, nil, PChar(prog_filename), nil, nil, False, CREATE_UNICODE_ENVIRONMENT, Env, PChar(ExtractFilePath(prog_filename)), si, pi);
      if Result then
      begin
        CloseHandle(pi.hThread);
        CloseHandle(pi.hProcess);
      end;
    finally
      DestroyEnvironmentBlock(Env);
    end;
  finally
    CloseHandle(hUserToken);
  end;
end;

Answer 2

您通过查找“好的”explorer.exe 获取会话 ID 的方法可能不适用于快速用户切换。

尝试使用WTSRegisterSessionNotification 让您的应用程序注册会话更改通知。然后，您将在会话切换时收到通知，并显示当前会话 ID。

注意以下几点：

要从服务接收会话更改通知，请使用 HandlerEx函数。