单击按钮时更改焦点颜色

Question

我的系统上的按钮很少，我尝试在单击按钮时更改颜色焦点。到目前为止，我的编码只能在单击时更改按钮颜色，但我希望我的系统能够在单击其他按钮时将按钮颜色重置为正常颜色。

我试图在网站上找到解决方案，但我真的不明白怎么做，因为他们的示例对我来说太复杂了。

这是我更改按钮颜色焦点的简单代码。

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Me.Button1.BackColor = Color.Gainsboro
    Me.Button1.ForeColor = Color.Black
End Sub

请帮助我。谢谢。

Answer 1

由于用户无需点击即可专注于按钮，因此最好处理按钮的GotFocus 和LostFocus 事件并将您的逻辑放在那里。

在下面的代码中，我为表单中的所有按钮分配了一个处理程序，并将原始ForeColor 和BackColor 存储在Tag 属性的数据结构中。然后在GotFocus 中，我将ForeColor 和BackColor 设置为所需的focusedForeColor 和focusedBackColor。同样在LostFocus 中，我恢复了之前存储在Tag 中的原始前景色和背景色。

将此代码粘贴到您的表单代码中就足够了，它将适用于所有按钮：

'Change these to your desired color
Private focusedForeColor As Color = Color.Black
Private focusedBackColor As Color = Color.Gainsboro

Private Function GetAllControls(control As Control) As IEnumerable(Of Control)
    Dim controls = control.Controls.Cast(Of Control)()
    Return controls.SelectMany(Function(ctrl) GetAllControls(ctrl)).Concat(controls)
End Function

Public Sub New()
    InitializeComponent()
    Me.GetAllControls(Me).OfType(Of Button)().ToList() _
      .ForEach(Sub(b)
                   b.Tag = Tuple.Create(b.ForeColor, b.BackColor)
                   AddHandler b.GotFocus, AddressOf b_GotFocus
                   AddHandler b.LostFocus, AddressOf b_LostFocus
               End Sub)
End Sub

Private Sub b_LostFocus(sender As Object, e As EventArgs)
    Dim b = DirectCast(sender, Button)
    Dim colors = DirectCast(b.Tag, Tuple(Of Color, Color))
    b.ForeColor = colors.Item1
    b.BackColor = colors.Item2
End Sub

Private Sub b_GotFocus(sender As Object, e As EventArgs)
    Dim b = DirectCast(sender, Button)
    b.ForeColor = focusedForeColor
    b.BackColor = focusedBackColor
End Sub

Answer 2

在声明部分创建 2 个颜色变量，一个用于背景属性，另一个用于前景色属性。您必须在表单的事件加载中将 Button1 的背景颜色和前景颜色属性分配给这些变量。当您单击 Button1 时，它会随着您所做的代码而改变，当您单击另一个按钮时，它会通过使用颜色变量恢复 Button1 的颜色。我希望这个解释对你有所帮助。下面是完整的代码以供进一步说明。

公开课表1 Dim bgColor, foColor As Color

Private Sub Button1_Click(sender As Object, e As EventArgs) _
    Handles Button1.Click
    Button1.BackColor = Color.Yellow
    Button1.ForeColor = Color.Blue
End Sub

Private Sub Button2_Click(sender As Object, e As EventArgs) _
    Handles Button2.Click
    Button1.BackColor = bgColor
    Button1.ForeColor = foColor
End Sub

Private Sub Form1_Load(sender As Object, e As EventArgs) _
    Handles MyBase.Load
    bgColor = Button1.BackColor
    foColor = Button1.ForeColor
End Sub

结束类