带复选框的树视图 - 添加复选框行为答案

【问题标题】：Treeview with checkboxes - adding checkbox behaviour带复选框的树视图 - 添加复选框行为
【发布时间】：2016-09-07 20:52:50
【问题描述】：

我正在创建带有复选框的 Treeview。我想出了如何将复选框切换到节点（procedure ToggleTreeViewCheckBoxes）。我添加了带有复选框位图的TImageList 组件，并在OnClick treeview 事件中更改了StateIndex。它工作正常，但我想为此添加其他行为。

我以创建树视图结构为例：

根 1
- 父 1（复选框）
  - 孩子 1（复选框）
  - 孩子 2（复选框）
- 父 2（复选框）
  - 孩子 1（复选框）
  - 孩子 2（复选框）
根 2
- 父 1（复选框）
  - 孩子 1（复选框）
  - 孩子 2（复选框）
- 父 2（复选框）
  - 孩子 1（复选框）
  - 孩子 2（复选框）

下面我附上我为创建树视图和添加节点、复选框而准备的示例代码。

unit TreeViewCheckboxes;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, System.ImageList, Vcl.ImgList,
  Vcl.ComCtrls;

type
  TForm5 = class(TForm)
    ImageList1: TImageList;
    TreeView1: TTreeView;
    procedure FormCreate(Sender: TObject);
    procedure TreeView1Click(Sender: TObject);
  private
    { Private declarations }
    procedure ToggleTreeViewCheckBoxes(Node:TTreeNode; cUnChecked, cChecked: Integer);
  public
    { Public declarations }
  end;

var
  Form5: TForm5;

const
  cStateUnCheck = 1;
  cStateChecked = 2;

   aRootList: Array[1..2] of String =
   (
      'Root 1',
      'Root 2'
   );

implementation

{$R *.dfm}

{ TForm5 }

procedure TForm5.FormCreate(Sender: TObject);
var
   RootNode: TTreeNode;
   ParentNode: TTreeNode;
   ChildNode: TTreeNode;
   i: Integer;
begin
   for i := 1 to High(aRootList) do
   begin
      RootNode := TreeView1.Items.Add(nil, aRootList[i]);

      ParentNode := TreeView1.Items.AddChild(RootNode, 'Parent 1');
      ParentNode.StateIndex := 1;
      ChildNode := TreeView1.Items.AddChild(ParentNode, 'Child 1');
      ChildNode.StateIndex := 1;
      ChildNode := TreeView1.Items.AddChild(ParentNode, 'Child 2');
      ChildNode.StateIndex := 1;    

      ParentNode := TreeView1.Items.AddChild(RootNode, 'Parent 2');
      ParentNode.StateIndex := 1;
      ChildNode := TreeView1.Items.AddChild(ParentNode, 'Child 1');
      ChildNode.StateIndex := 1;
      ChildNode := TreeView1.Items.AddChild(ParentNode, 'Child 2');
      ChildNode.StateIndex := 1;
   end;
end;

procedure TForm5.ToggleTreeViewCheckBoxes(Node: TTreeNode; cUnChecked,
  cChecked: Integer);
begin
   if Assigned(Node) then
   begin
      if Node.StateIndex = cUnChecked then
         Node.StateIndex := cChecked
      else if Node.StateIndex = cChecked then
         Node.StateIndex := cUnChecked;
   end;
end;

procedure TForm5.TreeView1Click(Sender: TObject);
var
   P: TPoint;
begin
   GetCursorPos(P);
   P := TreeView1.ScreenToClient(P);
   if (htOnStateIcon in TreeView1.GetHitTestInfoAt(P.X, P.Y)) then
      ToggleTreeViewCheckBoxes(TreeView1.Selected, cStateUnCheck, cStateChecked);
end;    
end.

问题：

1) 我该怎么做：如果我点击任何Parent 复选框节点，所有子节点都未选中？

2) 你知道动态添加节点并为所有孩子设置StateIndex 的更好方法吗？我的意思是不要每次都使用 line ChildNode.StateIndex := 1;

【问题讨论】：

标准 Win32 TreeView 控件本机支持复选框（请参阅TVS_CHECKBOXES window style），但TTreeView VCL 组件至今仍不支持该功能（RSP-15270 )。
确实是这样，但是我发现了："你可以通过覆盖TTreeView的CreateParams过程，为控件指定TVS_CHECKBOXES样式，给treeview添加复选框。结果是所有节点在树视图中将附加复选框。此外，不能再使用 StateImages 属性，因为 WC_TREEVIEW 在内部使用此图像列表来实现复选框“。我不会在每个节点中添加复选框。

标签： delphi checkbox treeview

【解决方案1】：

1) 我该如何做这样的事情：如果我点击任何父复选框节点，所有子节点都未选中？

你必须手动遍历所有的孩子，例如：

procedure TForm5.SetTreeViewCheckState(Node: TTreeNode; StateIndex: Integer; Recursive: Boolean);
begin
  Node.StateIndex := StateIndex;
  if not Recursive then Exit;
  for I := 0 to Node.Count-1 do
    SetTreeViewCheckState(Node.Item[I], StateIndex, True);
end;

procedure TForm5.ToggleTreeViewCheckBoxes(Node: TTreeNode);
var
  I: Integer;
begin
  if Assigned(Node) then
  begin
    if Node.StateIndex = cStateUnCheck then
      SetTreeViewCheckState(Node, cStateChecked, False);
    else if Node.StateIndex = cStateChecked then
      SetTreeViewCheckState(Node, cStateUnCheck, True);
  end;
end;

2) 您知道动态添加节点并为所有子节点设置 StateIndex 的更好方法吗？我的意思是不要每次都使用 line ChildNode.StateIndex := 1;

抱歉，这是唯一的方法。但是你可以将它包装在一个函数中：

procedure TForm5.FormCreate(Sender: TObject);
var
  RootNode: TTreeNode;
  ParentNode: TTreeNode;
  i: Integer;
begin
  for i := Low(aRootList) to High(aRootList) do
  begin
    RootNode := TreeView1.Items.Add(nil, aRootList[i]);

    ParentNode := AddChildNodeWithState(RootNode, 'Parent 1');
    AddChildNodeWithState(ParentNode, 'Child 1');
    AddChildNodeWithState(ParentNode, 'Child 2');

    ParentNode := AddChildNodeWithState(RootNode, 'Parent 2');
    AddChildNodeWithState(ParentNode, 'Child 1');
    AddChildNodeWithState(ParentNode, 'Child 2');
  end;
end;

function TForm5.AddChildNodeWithState(AParentNode: TTreeNode, const ACaption: String; AStateIndex: Integer = 1): TTreeNode;
begin
  Result := TreeView1.Items.AddChild(AParentNode, ACaption);
  Result.StateIndex := AStateIndex;
end;

或者，您可以创建一个class helper（您也可以将其用于切换逻辑）：

type
  TTreeNodeHelper = class helper for TTreeNode
  public
    function AddChildWithState(const ACaption: string; AStateIndex: Integer = 1): TTreeNode;
    procedure SetCheckState(StateIndex: Integer; Recursive: Boolean);
    procedure ToggleCheckState;
  end;

function TTreeNodeHelper.AddChildWithState(const ACaption: string; AStateIndex: Integer = 1): TTreeNode;
begin
  Result := Self.TreeView.Items.AddChild(Self, ACaption);
  Result.StateIndex := AStateIndex;
end;

procedure TTreeNodeHelper.SetCheckState(StateIndex: Integer; Recursive: Boolean);
begin
  Self.StateIndex := StateIndex;
  if not Recursive then Exit;
  for I := 0 to Self.Count-1 do
    Self.Item[I].SetCheckState(StateIndex, True);
end;

procedure TTreeNodeHelper.ToggleCheckState;
var
  I: Integer;
begin
  if Self.StateIndex = cStateUnCheck then
    SetCheckState(cStateChecked, False);
  else if Self.StateIndex = cStateChecked then
    SetCheckState(cStateUnCheck, True);
  end;
end;

procedure TForm5.FormCreate(Sender: TObject);
var
  RootNode: TTreeNode;
  ParentNode: TTreeNode;
  i: Integer;
begin
  for i := Low(aRootList) to High(aRootList) do
  begin
    RootNode := TreeView1.Items.Add(nil, aRootList[i]);

    ParentNode := RootNode.AddChildWithState('Parent 1');
    ParentNode.AddChildWithState('Child 1');
    ParentNode.AddChildWithState('Child 2');

    ParentNode := RootNode.AddChildWithState('Parent 2');
    ParentNode.AddChildWithState('Child 1');
    ParentNode.AddChildWithState('Child 2');
  end;
end;

procedure TForm5.TreeView1Click(Sender: TObject);
var
  P: TPoint;
begin
  GetCursorPos(P);
  P := TreeView1.ScreenToClient(P);
  if (htOnStateIcon in TreeView1.GetHitTestInfoAt(P.X, P.Y)) then
    TreeView1.GetNodeAt(P.X, P.Y).ToggleCheckState;
end;

如果您使用的是不支持类助手的旧版 Delphi，您可以从 TTreeNode 派生一个类，并将其与 TreeView 的 OnCreateNodeClass 事件一起使用，例如：

type
  TMyTreeNode = class(TTreeNode)
  public
    function AddChildWithState(const ACaption: string; AStateIndex: Integer = 1): TTreeNode;
    procedure SetCheckState(StateIndex: Integer; Recursive: Boolean);
    procedure ToggleCheckState;
  end;

function TMyTreeNode.AddChildWithState(const ACaption: string; AStateIndex: Integer = 1): TTreeNode;
begin
  Result := Self.TreeView.Items.AddChild(Self, ACaption);
  Result.StateIndex := AStateIndex;
end;

procedure TMyTreeNode.SetCheckState(StateIndex: Integer; Recursive: Boolean);
begin
  Self.StateIndex := StateIndex;
  if not Recursive then Exit;
  for I := 0 to Self.Count-1 do
    TMyTreeNode(Self.Item[I]).SetCheckState(StateIndex, True);
end;

procedure TMyTreeNode.ToggleCheckBoxes;
var
  I: Integer;
begin
  if Self.StateIndex = cStateUnCheck then
    SetCheckBoxes(cStateChecked, cStateUnChecked);
  else if Self.StateIndex = cStateChecked then
    SetCheckBoxes(cStateUnCheck, cStateUnChecked);
  end;
end;

procedure TForm5.FormCreate(Sender: TObject);
var
  RootNode: TTreeNode;
  ParentNode: TTreeNode;
  i: Integer;
begin
  for i := Low(aRootList) to High(aRootList) do
  begin
    RootNode := TreeView1.Items.Add(nil, aRootList[i]);

    ParentNode := TMyTreeNode(RootNode).AddChildWithState('Parent 1');
    TMyTreeNode(ParentNode).AddChildWithState('Child 1');
    TMyTreeNode(ParentNode).AddChildWithState('Child 2');

    ParentNode := TMyTreeNode(RootNode).AddChildWithState('Parent 2');
    TMyTreeNode(ParentNode).AddChildWithState('Child 1');
    TMyTreeNode(ParentNode).AddChildWithState('Child 2');
  end;
end;

procedure TForm5.TreeView1Click(Sender: TObject);
var
  P: TPoint;
begin
  GetCursorPos(P);
  P := TreeView1.ScreenToClient(P);
  if (htOnStateIcon in TreeView1.GetHitTestInfoAt(P.X, P.Y)) then
    TMyTreeNode(TreeView1.GetNodeAt(P.X, P.Y)).ToggleCheckState;
end;    

procedure TForm5.TreeView1CreateNodeClass(Sender: TCustomTreeView; var NodeClass: TTreeNodeClass)
begin
  NodeClass := TMyTreeNode;
end;

【讨论】：

首先，感谢您的详尽而宝贵的回复。我发现第一个问题还有一个问题（单击父节点时取消选中子节点）。示例：如果我们转到子节点并检查它，然后我们检查父节点，则所有子节点都未选中。你知道怎么解决吗？
@astack：嗯，这就是你要求的：“如果我点击任何父复选框节点，所有子节点都未选中。 “你想让它做什么呢？如果选中了父节点，则应检查所有子节点，如果未选中父节点，则应取消选中所有子节点？这是有道理的。只需相应地更改SetCheckBoxes() 的最后一个参数（或完全删除该参数）。或者，您是否希望所有子节点都未选中，即使父节点被选中，但跳过之前选中的任何子节点？这有点复杂。
我的意思是：“如果我在 cStateChecked 模式下单击父节点，则所有子节点都未选中”。问题是如果我检查一些子节点并单击 cStateUnchecked 中的父节点，则所有子节点都未选中。在这种情况下，子节点应该独立于父节点，我应该能够保持它们的选中状态。你知道我的意思吗？
如果父节点当前被选中并且单击取消选中它，那么它的所有子节点都应该被取消选中，对吗？显示的代码正是这样做的。如果父节点当前未选中并且单击检查它，则其已经选中的子节点应该保持选中，对吗？当前未选中的子节点呢？他们应该切换选中还是保持不选中？如果是前者，则在将父级切换为选中时将SetCheckBoxes() 的第二个参数设置为cStateChecked。如果是后者，只需自行切换父节点，完全忽略其子节点
右 - 如果父节点当前被选中，点击它后所有子节点都应该被取消选中（它有效），但是如果父节点当前未被选中并且我们单击检查，我们不应该检查所有子节点，但我们应该保持它们的状态（它有效）。一个问题只是在一种情况下，示例：父节点是unchecked，但是这个父节点中的一个子节点是checked，我们点击在 unchecked 父节点上进行检查 - 在这种情况下，所有 child 节点 都是 unchecked 但我们应该保持它们的状态 .希望现在你会清楚。