通过 WebBrowser 下载鼠标指针下的图像

Question

我正在使用 WebBrowser 控件导航到 Google 图片。目的是能够右键单击任何图像并下载并填充 PictureBox 背景。

我有自己的ContextMenuStrip，上面有复制，并且禁用了内置的上下文菜单。

我遇到的问题是从CurrentDocument.MouseMove 返回的坐标总是相对于第一张（左上角）图像。
因此，如果我想要的图像是页面上的第一个图像，我的代码可以正常工作，但是单击任何其他图像总是返回第一个图像的坐标。

看起来坐标是相对于每个图像而不是页面的。

Private WithEvents CurrentDocument As HtmlDocument
Dim MousePoint As Point
Dim Ele As HtmlElement

Private Sub Google_covers_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    WebBrowser1.IsWebBrowserContextMenuEnabled = False
    WebBrowser1.ContextMenuStrip = ContextMenuStrip1
End Sub

Private Sub WebBrowser1_Navigated(sender As Object, e As WebBrowserNavigatedEventArgs) Handles WebBrowser1.Navigated
    CurrentDocument = WebBrowser1.Document

End Sub
Private Sub CurrentDocument_MouseMove(sender As Object, e As HtmlElementEventArgs) Handles CurrentDocument.MouseMove
    MousePoint = New Point(e.MousePosition.X, e.MousePosition.Y)
    Me.Text = e.MousePosition.X & " | " & e.MousePosition.Y
End Sub

Private Sub ContextMenuStrip1_Opening(sender As Object, e As System.ComponentModel.CancelEventArgs) Handles ContextMenuStrip1.Opening
    Ele = CurrentDocument.GetElementFromPoint(MousePoint)
    If Ele.TagName = "IMG" Then
        CopyToolStripMenuItem.Visible = True
    Else
        CopyToolStripMenuItem.Visible = False
    End If
End Sub

Private Sub CopyToolStripMenuItem_Click(sender As System.Object, e As System.EventArgs) Handles CopyToolStripMenuItem.Click
    Dim ToImg = Ele.GetAttribute("src")
    mp3_row_edit.PictureBox1.BackgroundImage = New System.Drawing.Bitmap(New IO.MemoryStream(New System.Net.WebClient().DownloadData(ToImg)))
    ToImg = Nothing
End Sub

Answer 1

此代码允许使用标准 WebBrowser 控件导航到 Google 图片搜索页面并通过鼠标右键单击来选择/下载图片。

要对其进行测试，请将 WebBrowser 控件和 FlowLayoutPanel 拖放到表单上，然后导航到 Google 图片搜索页面。

须知：

• WebBrowser.DocumentCompleted：每次完成主 HtmlDocument 页面内的子文档之一时，都会引发此事件。因此，它可以多次提高。我们需要检查WebBrowser.ReadyState= WebBrowserReadyState.Complete是否。
  阅读这些说明：How to get an HtmlElement value inside Frames/IFrames?
• 可以通过两种不同的方式将 Google 搜索页面中的图像插入到文档中：使用 Base64Encoded 字符串 和使用经典的 src=[URI] 格式.我们需要准备好两者兼得。
• 鼠标点击位置可以用绝对或相对坐标表示，由e.ClientMousePosition 或e.OffsetMousePosition 引用。
  在此处阅读有关此功能的说明：Getting mouse click coordinates in a WebBrowser Document
• WebBrowser 仿真模式可能很重要。我们应该使用当前机器上可用的最新兼容模式。
  阅读此答案并应用所需的修改以使最新的 Internet Explorer 模式可用：How can I get the WebBrowser control to show modern contents?。

---

请注意，当当前文档完成时，事件处理程序会被连接起来，而当浏览器导航到另一个页面时，事件处理程序会被删除。这可以防止对DocumentCompleted 事件的意外调用。

当前文档完成后，在图像上单击鼠标右键会创建一个新的 PictureBox 控件，该控件将添加到 FlowLayouPanel 以进行演示。

鼠标单击处理程序 (Protected Sub OnHtmlDocumentClick()) 中的代码检测当前图像是 Base64Encoded 字符串还是外部源 URI 。
在第一种情况下，它调用Convert.FromBase64String 将字符串转换为字节数组，在第二种情况下，它使用 WebClient 类将图像下载为字节数组。

在这两种情况下，然后将数组传递给另一个方法 (Private Function GetBitmapFromByteArray())，该方法使用 Image.FromStream() 和 从数组返回图像>MemoryStream 使用 Byte 数组初始化。

这里的代码没有执行空检查和类似的防故障测试。应该的，这取决于你。

Public Class frmBrowser
    Private WebBrowserDocumentEventSet As Boolean = False
    Private base64Pattern As String = "base64,"

    Private Sub frmBrowser_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        WebBrowser1.ScriptErrorsSuppressed = True
        WebBrowser1.IsWebBrowserContextMenuEnabled = False
    End Sub

    Private Sub WebBrowser1_DocumentCompleted(sender As Object, e As WebBrowserDocumentCompletedEventArgs) Handles WebBrowser1.DocumentCompleted
        If WebBrowser1.ReadyState = WebBrowserReadyState.Complete AndAlso WebBrowserDocumentEventSet = False Then
            WebBrowserDocumentEventSet = True
            AddHandler WebBrowser1.Document.MouseDown, AddressOf OnHtmlDocumentClick
        End If
    End Sub

    Protected Sub OnHtmlDocumentClick(sender As Object, e As HtmlElementEventArgs)
        Dim currentImage As Image = Nothing

        If Not (e.MouseButtonsPressed = MouseButtons.Right) Then Return
        Dim source As String = WebBrowser1.Document.GetElementFromPoint(e.ClientMousePosition).GetAttribute("src")

        If source.Contains(base64Pattern) Then
            Dim base64 As String = source.Substring(source.IndexOf(base64Pattern) + base64Pattern.Length)
            currentImage = GetBitmapFromByteArray(Convert.FromBase64String(base64))
        Else
            Using wc As WebClient = New WebClient()
                currentImage = GetBitmapFromByteArray(wc.DownloadData(source))
            End Using
        End If

        Dim p As PictureBox = New PictureBox() With {
            .Image = currentImage,
            .Height = Math.Min(FlowLayoutPanel1.ClientRectangle.Height, FlowLayoutPanel1.ClientRectangle.Width)
            .Width = .Height,
            .SizeMode = PictureBoxSizeMode.Zoom
        }
        FlowLayoutPanel1.Controls.Add(p)
    End Sub

    Private Sub WebBrowser1_Navigating(sender As Object, e As WebBrowserNavigatingEventArgs) Handles WebBrowser1.Navigating
        If WebBrowser1.Document IsNot Nothing Then
            RemoveHandler WebBrowser1.Document.MouseDown, AddressOf OnHtmlDocumentClick
            WebBrowserDocumentEventSet = False
        End If
    End Sub

    Private Function GetBitmapFromByteArray(imageBytes As Byte()) As Image
        Using ms As MemoryStream = New MemoryStream(imageBytes)
            Return DirectCast(Image.FromStream(ms).Clone(), Image)
        End Using
    End Function
End Class