查找数组 vba 中的重复数字答案

【问题标题】：Find repeating numbers in array vba查找数组 vba 中的重复数字
【发布时间】：2017-03-01 20:03:36
【问题描述】：

我正在尝试在 vba 中创建一个大小为 50 的数组，其中包含 0 到 20 之间的随机数，然后将该数组中重复的数字提取到另一个数组中。

Sub Problem10()
Dim numbers() As Double, odd() As Double, even() As Double, five() As Double, repeating() As Double, x As Integer, i As Integer, sOdd As Integer, sEven As Integer, sFive As Integer, sNumbers As Integer, sRepeating As Integer, y As Integer, listed As Boolean
sRepeating = 0
sNumbers = 50
For i = 1 To sNumbers
    ReDim Preserve numbers(i)
    numbers(i) = Int(20 * rnd) 
    'find repeating numbers
    For x = 1 To i
        If numbers(x) = numbers(i) And i <> x Then
            'check if there are any repeated numbers already
            If sRepeating > 0 And listed = False Then
                For y = 1 To sRepeating
                   'check if the number is already listed as a repeated number
                    If numbers(i) = repeating(y) Then
                        listed = True
                    Else
                        sRepeating = sRepeating + 1
                        ReDim Preserve repeating(sRepeating)
                            repeating(sRepeating) = numbers(i)
                            Cells(sRepeating + 1, 4).Value = repeating(sRepeating)
                            listed = True
                    End If
                Next y
            End If
        End If
    Next x
    Cells(i + 1, 5).Value = numbers(i)
Next i
End Sub

我能够创建带有随机数 (numbers()) 的数组，然后提取具有偶数、奇数和 5 倍数的新数组。但是，我不知道如何仅提取重复数字。现在，这只会找到第一个重复的数字，没有别的。

【问题讨论】：

有很多方法可以解决这个问题。您可以使用字典来保存数组中现有数字的记录（键）和它们的计数（项目）。然后，如果计数为 3 或更高，则可以使用简单循环将字典转换为数组。

标签： arrays excel vba integer repeat

【解决方案1】：

考虑下面的例子：

Option Explicit

Sub Test()

    Dim i
    Dim numbers(0 To 49)
    Dim repeating()
    Dim q

    ' Fill array with random numers
    Randomize
    For i = 0 To 49
        numbers(i) = Int(20 * Rnd)
    Next

    ' Filter repeating elements
    With CreateObject("Scripting.Dictionary")
        ' Count each number qty
        For i = 0 To 49
            .Item(numbers(i)) = .Item(numbers(i)) + 1
        Next
        ' Remove non-repeating
        For Each q In .Keys()
            If .Item(q) = 1 Then .Remove q
        Next
        ' Retrieve array
        repeating = .Keys()
    End With

    Debug.Print Join(numbers)
    Debug.Print Join(repeating)

End Sub

【讨论】：