vb.net 特化/重载泛型

Question

我倾向于讨厌代码中的重复，所以当我遇到唯一不同的是类型的问题时，我倾向于使用泛型。来自 C++ 背景，我发现 vb.net 的版本相当令人沮丧，我知道 C++ 有模板专业化，我猜 vb.net 没有 所以我所拥有的是一组例程，它们执行完全相同的代码，而不管传递的类型如何。

类似的东西

Public Sub decision(Of T)(ByVal a As T, ByVal b As Integer)
  If b > 10 then
    gt(a)
  Else
    lt(a)
  End If
End Sub

我只将两种类型传递给例程，字符串和整数，这些例程对字符串的处理与对整数的处理不同。

Public Sub gt(ByVal a As String)
Public Sub gt(ByVal a As Integer)

Public Sub lt(ByVal a As String)
Public Sub lt(ByVal a As Integer)

这是我对 vb.net vs C++ 感到沮丧的地方，AFAIK，C++ 会在编译时检查类型，并且只针对发送到决策的类型。但是，在 vb.net 中，我收到 T 类型无法转换为字符串或整数的错误

Error   3   Overload resolution failed because no accessible 'gt' can be called with these arguments:
    'Public Sub gt(a As String)': Value of type 'T' cannot be converted to 'String'.
    'Public Sub gt(a As Integer)': Value of type 'T' cannot be converted to 'Integer'.

我尝试了约束Public Sub decision(Of T As {String, Integer})(ByVal a As T, ByVal b As Integer)，但约束必须是可继承的类，因此既不能使用String，也不能使用Integer。

我的下一个解决方案是添加gt 和lt 的通用版本：

Public Sub lt(Of T)(ByVal a As T)
  Debug.Fail("Not Implemented")
End Sub

Public Sub lt(Of T)(ByVal a As T)
  Debug.Fail("Not Implemented")
End Sub

嘿！没有更多的编译错误，但是唯一被调用的例程是gt 和lt 的通用版本。鉴于前面的无法转换错误，我认为这是有道理的。我之前在泛型例程的非泛型重载时遇到过这个问题，当时我找不到解决方案，现在也找不到解决方案。

有什么我遗漏的东西可以使这种类型的重载成为可能吗？

编辑：一个完整​​的工作示例

Module Module1
   Sub Main()

      decision(1, 5)
      decision(1, 10)
      decision("hello world", 5)
      decision("hello world", 10)

   End Sub


   Public Sub decision(Of T)(ByVal a As T, ByVal b As Integer)
      If b > 10 Then
         gt(a)
      Else
         lt(a)
      End If
   End Sub

   Public Sub gt(ByVal a As String)
      Debug.WriteLine(" gt string:  " + a)
   End Sub
   Public Sub gt(ByVal a As Integer)
      Debug.WriteLine(" gt integer: " + a.ToString)
   End Sub

   Public Sub lt(ByVal a As String)
      Debug.WriteLine(" lt string: " + a)
   End Sub
   Public Sub lt(ByVal a As Integer)
      Debug.WriteLine(" lt integer: " + a.ToString)
   End Sub

#If False Then
   Public Sub gt(Of T)(ByVal a As T)
      Debug.Fail("Not implemented")
   End Sub
   Public Sub lt(Of T)(ByVal a As T)
      Debug.Fail("Not implemented")
   End Sub
#End If
End Module

Answer 1

来自Differences Between C++ Templates and C# Generics（同样适用于 VB .NET）：

C++ 允许代码可能不适用于 模板，然后检查用作类型的特定类型 范围。 C# 要求类中的代码以这种方式编写 它将适用于任何满足约束的类型。为了 例如，在 C++ 中，可以编写一个使用 算术运算符 + 和 - 在类型参数的对象上，其中 在模板实例化时会产生错误 使用不支持这些运算符的类型。 C# 不允许这样做； 唯一允许的语言结构是那些可以推断的 来自约束。

我无法用 .NET 泛型解决您的问题。但是您可以通过使用 lambda 和闭包来避免重复逻辑，我也认为在 .NET 中这样做是一种更自然的方式：

Public Sub Decision(ByVal a As String, ByVal b As Integer)
    Decision(b, Sub() gt(a), Sub() lt(a))
End Sub

Public Sub Decision(ByVal a As Integer, ByVal b As Integer)
    Decision(b, Sub() gt(a), Sub() lt(a))
End Sub

Private Sub decision(ByVal b As Integer, ByVal gt As Action, ByVal lt As Action)
    If b > 10 Then
        gt()
    Else
        lt()
    End If
End Sub

Public Sub gt(ByVal a As String)
    Debug.WriteLine(" gt string:  " + a)
End Sub
Public Sub gt(ByVal a As Integer)
    Debug.WriteLine(" gt integer: " + a.ToString)
End Sub

Public Sub lt(ByVal a As String)
    Debug.WriteLine(" lt string: " + a)
End Sub
Public Sub lt(ByVal a As Integer)
    Debug.WriteLine(" lt integer: " + a.ToString)
End Sub