从另一个调用一个重载的构造函数有意义吗？

Question

如果我有两个重载的构造函数，一个没有参数，一个有参数：

constructor Create; overload;
constructor Create(Param: TObject); overload;

如果我想让第一个中的代码运行，那么在第二个中调用它是否有意义？并且继承先调用父构造函数？

constructor TMyType.Create(Param: TObject);
begin
  inherited Create;
  Create;
  FParam := Param;
end;

谢谢！

Answer 1

如果我希望第一个代码运行，那么在第二个代码中调用它是否有意义并且也继承了先调用父构造函数？

没有。因为您的第一个构造函数应该自己调用继承的构造函数，所以最后继承的构造函数会被调用两次，这很可能不会发生。

否则，如果你的无参数TMyType.Create() 没有调用继承的，那么它就不是一个合适的构造函数，应该被删除。

所以正确的做法是这样的：

constructor TMyType.Create(Param: TObject); overload;
begin
  Create();
  FParam := Param;
end;

constructor TMyType.Create();  overload;
begin
  inherited Create(); // for both constructors

  ...some common code
end;

但是在 Delphi 中还有另一种可能性。

constructor Create; overload;
constructor Create(Param: TObject); overload;
procedure AfterConstruction; override;


constructor TMyType.Create(Param: TObject); 
begin
  inherited Create(); 

  FParam := Param;
end;

constructor TMyType.Create();
begin
  inherited ; 

 ... maybe some extra code
end;

procedure TMyType.AfterConstruction();
begin
    inherited;

  ...some common code
end;

请注意区别，什么时候执行“通用代码”，什么时候执行“FParam := Param;”

在第一种方式中，流程就像

• 创建（参数）
• ..创建()
• ....继承的 Create()
• ....通用代码
• ..FParam := 参数；
• AfterConstruction（空）

在第二个中，顺序会有所不同

• 创建（参数）或创建（）
• ..继承的 Create()
• ..FParam := 参数；
• 施工后
• ..通用代码

如您所见，这些块的执行顺序颠倒了。

---

但是，也许您根本不需要多个构造函数？

constructor TMyType.Create(const Param: TObject = nil); 
begin
  inherited; 

 ... Some code

  FParam := Param;
end;

Answer 2

是的，您的代码非常合理，并且构造函数的调用完全符合预期。

Delphi 对象模型支持调用继承构造函数的构造函数和不调用继承构造函数的构造函数。

如果你不确定，试试这个：

program Project5;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TMyBase = class
    constructor Create;
  end;

  TMyType = class(TMyBase)
    constructor Create; overload;
    constructor Create(Param: TObject); overload;
  end;

constructor TMyBase.Create;
begin
  Writeln('TMyBase.Create');
end;

constructor TMyType.Create;
begin
  Writeln('TMyType.Create');
end;

constructor TMyType.Create(Param: TObject);
begin
  inherited Create;
  Create;
  Writeln('TMyType.Create(Param)');
end;

begin
  TMyType.Create(TObject.Create);
  Readln;
end.