F# 处理任务取消

Question

我很难理解为什么有些代码永远不会执行。

考虑这种扩展方法：

type WebSocketListener with
  member x.AsyncAcceptWebSocket = async {
    try
        let! client = Async.AwaitTask <| x.AcceptWebSocketAsync Async.DefaultCancellationToken
        if(not (isNull client)) then
            return Some client
        else
            return None
    with
        | :? System.Threading.Tasks.TaskCanceledException -> 
        | :? AggregateException ->
            return None
  }

我知道当取消令牌被取消时，AcceptSocketAsync 会抛出 TaskCanceledException。我已经签入了一个 C# 应用程序。这个想法是返回None。

但是，这永远不会发生。如果我在最后一个return None 甚至if 表达式中放置一个断点，那么当取消令牌被取消时，它永远不会停在那里。而且我知道它正在 Async.AwaitTask 中等待，因为如果在取消之前，其他客户端连接，它会工作并在断点处停止。

我有点迷茫，为什么异常丢了？

Answer 1

取消使用 F# 异步中的特殊路径 - Async.AwaitTask 会将已取消任务的执行重新路由到取消继续。如果您想要不同的行为 - 您始终可以手动执行此操作：

type WebSocketListener with
  member x.AsyncAcceptWebSocket = async {
    let! ct = Async.CancellationToken
    return! Async.FromContinuations(fun (s, e, c) ->
        x.AcceptWebSocketAsync(ct).ContinueWith(fun (t: System.Threading.Tasks.Task<_>) -> 
            if t.IsFaulted then e t.Exception
            elif t.IsCanceled then s None // take success path in case of cancellation
            else 
            match t.Result with
            | null -> s None
            | x -> s (Some x)
        )
        |> ignore
    )
  }