在Fortran中初始化参数化派生类型的参数大小数组？

Question

Fortran 允许参数化派生类型元素的大小。但是，在类型声明中可以为固定大小的元素分配默认值的情况下，似乎没有办法用于参数化条目：

PROGRAM main
  IMPLICIT NONE

  TYPE data1
     INTEGER :: array(5) = 2   ! allowed
  END type data1

  TYPE data2(n)
     INTEGER, LEN :: n
     INTEGER :: array(n) = 2   ! incorrect: error #8737 with intel fortran 19,
  END type data2               !            ignored by gfortran 8.2.1

END PROGRAM main

分配默认值很方便，因为它可以避免每次使用类型时都重复初始化，但对于参数大小的字段，这是不允许的； Gfortran 只是默默忽略默认值，Intel Fortran 报错

error #8737: For a default initialized component every type parameter and array bound
             must be a constant expression.   [ARRAY]

是否有任何语法允许定义默认值？

Answer 1

此类组件不能有默认初始化。

正如英特尔 Fortran 错误消息所述，具有初始化表达式的组件的数组边界必须是常量表达式（这是 Fortran 2018 的约束 C762）。长度类型参数不能用作常量表达式。

没有其他语法可以为组件指定默认值。

种类类型参数可以在常量表达式中使用，因此具有该类型种类参数给定边界的组件可以具有默认初始化。

Answer 2

您可以创建一个构造函数，该构造函数采用长度参数来创建对象

module datatypes

type data2(n)
    integer, len :: n
    integer :: array(n)
contains        
    procedure, pass :: data2_fill2
end type

interface data2
    module procedure new_data2
end interface

contains
    subroutine data2_fill2(this)
        class(data2(*)) :: this
        this%array = 2
    end subroutine
    function new_data2(n) result(r)
        integer, intent(in) :: n
        type(data2(n)) :: r
        call r%data2_fill2()
    end function
end module

program Main
use datatypes
    type(data2(3)) :: mydata

    mydata = data2(100)

    print *, "Size of array ", size(mydata%array)

    if( mydata%array(1) /= 2) then
        print *, "Something went wrong"
    end if


end program

Answer 3

您在不同的编译器中发现了一个错误。您的代码符合标准。稍微充实一下代码，下面应该打印'2 2 2'。

program main

implicit none
!
! F2018, 7.5.1, page 64: A derived type can be parameterized by one or
! more type parameters, each of which is defined to be either a kind
! or length type parameter and can have a default value.
!
! F2018, 7.5.3.1, page 69: A type parameter may be used as a primary in
! a specification expression (10.1.11) in the derived-type-def.
!
! 10.1.11 Specification expression (page 156)
! ...
!    R1028 specification-expr  is scalar-int-expr
!
! C1010 (R1028) The scalar-int-expr shall be a restricted expression.
!
! A restricted expression is an expression in which each operation is
! intrinsic or defined by a specification function and each primary is
! ...
! (13) a type parameter of the derived type being defined,
!
type data2(n)
   integer, len :: n
   integer :: array(n) = 2
end type data2

type(data2(n=3)) :: a

print *, a%array  ! This should print 2 2 2

end program main

gfortran 编译代码，但打印 '0 0 0'，所以 gfortran 在应用组件初始化时存在错误。