Unity3d中的轮廓着色器答案

【问题标题】：Outline Shader in Unity3dUnity3d中的轮廓着色器
【发布时间】：2014-01-25 10:18:55
【问题描述】：

我正在尝试将我从网上获得的这个着色器配置为具有白色轮廓而不是黑色轮廓。但是“_OutlineColor（“轮廓颜色”，颜色）=（1,1,1,1）”不起作用。我是统一的新手以及事情如何运作，所以我希望你能帮助我。这是完整的着色器：

Shader "Outlined/Diffuse" {
    Properties {
        _Color ("Main Color", Color) = (0,0,0,0)
        _OutlineColor ("Outline Color", Color) = (1,1,1,1)
        _Outline ("Outline width", Range (.002, 0.03)) = 5
        _MainTex ("Base (RGB)", 2D) = "white" { }
    }

CGINCLUDE
#include "UnityCG.cginc"

struct appdata {
    float4 vertex : POSITION;
    float3 normal : NORMAL;
};

struct v2f {
    float4 pos : POSITION;
    float4 color : COLOR;
};

uniform float _Outline;
uniform float4 _OutlineColor;

v2f vert(appdata v) {
    // just make a copy of incoming vertex data but scaled according to normal direction
    v2f o;
    o.pos = mul(UNITY_MATRIX_MVP, v.vertex);

    float3 norm   = mul ((float3x3)UNITY_MATRIX_IT_MV, v.normal);
    float2 offset = TransformViewToProjection(norm.xy);

    o.pos.xy += offset * o.pos.z * _Outline;
    o.color = _OutlineColor;
    return o;
}
ENDCG

    SubShader {
        //Tags {"Queue" = "Geometry+100" }
CGPROGRAM
#pragma surface surf Lambert

sampler2D _MainTex;
fixed4 _Color;

struct Input {
    float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
    fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
    o.Albedo = c.rgb;
    o.Alpha = c.a;
}
ENDCG

        // note that a vertex shader is specified here but its using the one above
        Pass {
            Name "OUTLINE"
            Tags { "LightMode" = "Always" }
            Cull Front
            ZWrite On
            ColorMask RGB
            Blend SrcAlpha OneMinusSrcAlpha
            //Offset 50,50

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            half4 frag(v2f i) :COLOR { return i.color; }
            ENDCG
        }
    }

    SubShader {
CGPROGRAM
#pragma surface surf Lambert

sampler2D _MainTex;
fixed4 _Color;

struct Input {
    float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
    fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
    o.Albedo = c.rgb;
    o.Alpha = c.a;
}
ENDCG

        Pass {
            Name "OUTLINE"
            Tags { "LightMode" = "Always" }
            Cull Front
            ZWrite On
            ColorMask RGB
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM
            #pragma vertex vert
            #pragma exclude_renderers gles xbox360 ps3
            ENDCG
            SetTexture [_MainTex] { combine primary }
        }
    }

    Fallback "Diffuse"
}

【问题讨论】：

在材质检查器中验证颜色是否为白色。 Unity 的 Inspector 设置取代了您在着色器中硬编码的值。
你能说得更具体点吗？什么不起作用？检查检查员在游戏过程中分配了什么颜色。还要尝试在游戏过程中更改分配给它的对象的颜色，以检查着色器本身是否存在错误。

标签： unity3d

【解决方案1】：

您分配给“_OutlineColor”的“(1,1,1,1)”描述了一个默认值。当您创建使用该着色器的新材质（此处为“轮廓/漫反射”）时，会考虑该值。只需创建新材质并将您的着色器分配给它。您会注意到这次的轮廓颜色将是白色。您也可以简单地在编辑器中选择您的材质并通过检查器窗口更改轮廓颜色。

至于您的问题 - 在您将着色器的主体从黑色 (0,0,0,1) 更改为白色 (1,1, 1,1）颜色（我认识着色器的主体，所以我假设为黑色）。这意味着默认的黑色已经分配给材料。如果你想改变颜色，就像我上面写的，通过编辑检查器在材料上做。

【讨论】：