【问题标题】:How do I make a list in CMake with the semicolon value?如何在 CMake 中使用分号值创建一个列表?
【发布时间】:2020-05-08 19:12:47
【问题描述】:

我认为它应该是非常微不足道的,但似乎不受支持...在 CMake 中甚至可以让列表的一个值包含分号吗?

原因非常简单——因为我在 Windows 上运行,而在 Windows 上,分号是一个环境变量(即PATH)中两个或多个文件夹之间的分隔符。

    list(
      APPEND
      MY_TEST_ENVIRONMENT
      "MY_FLAG=1"
    )

    # <...>

    list(
      APPEND
      MY_TEST_ENVIRONMENT
      "PATH=first_folder_path;second_folder_path"
    #                        ^--- here is the problem
    )

    # <...>


   set_property(TEST MyTests PROPERTY ENVIRONMENT ${MY_TEST_ENVIRONMENT})

我尝试删除和添加双引号,我尝试转义 \;,我尝试添加相同的环境变量两次 - 但这些都不起作用!

【问题讨论】:

  • 您能否也说明您打算如何使用该列表?您在列表中执行了哪些命令?您如何使用它来设置环境变量?
  • @squareskittles 添加了,但我期待这从我的变量名称中非常明显。这是环境变量设置

标签: windows list makefile cmake cmake-language


【解决方案1】:

通过使用反斜杠转义分号,您走在了正确的轨道上。但是,当在ENVIRONMENT 测试属性中设置列表时,这不是将使用列表的最后一个位置(并由 CMake 解释)。然后使用MY_TEST_ENVIRONMENT 列表填充CTestTestfile.cmake,CTest 稍后会读取该列表以设置您的测试环境。

简而言之,您需要 更多 个转义字符来将分号传播到测试环境。具体来说,使用双反斜杠 \\ 将 extra 反斜杠与 \; 转义分号一起转义到列表中。这是 CMake 的 escape characters 文档供参考。总共 三个 反斜杠应该可以工作:

list(
  APPEND
  MY_TEST_ENVIRONMENT
  "MY_FLAG=1"
)

# <...>

list(
  APPEND
  MY_TEST_ENVIRONMENT
  "PATH=first_folder_path\\\;second_folder_path"
#                         ^--- Use three backslashes here
)

# <...>

set_property(TEST MyTests PROPERTY ENVIRONMENT ${MY_TEST_ENVIRONMENT})

【讨论】:

    【解决方案2】:

    不幸的是,CMake 内部的列表只是用分号分隔的字符串。如果你这样做:

    set(MyList
        ABC
        DEF;GHI
    )
    

    您正在定义一个包含三个元素的列表。如果你偷看内容:

    message(${MyList})
    message("${MyList}")
    

    您将分别获得ABCDEFGHI 和ABC;DEF;GHI,因此无法知道在这两种情况下您实际上想要拥有多少个元素。大多数 CMake 命令,如 add_executable 或 target_compile_definitions 都以这种方式解释传递的参数,您将无法传递带有包含分号的元素的列表。

    请注意,当您将变量放在引号中时,分号不会被删除(参见上面的示例),因此如果您正在调用一些外部命令,例如 powershell 脚本,那么应该正确传递 PATH 变量。但是你不会为你的参数列表使用一个列表(因为元素是分号分隔的),而是构建你自己的空格分隔的字符串。

    【讨论】:

    • 我知道分号是 CMake 中的列表分隔符。所以这不是一个真正的答案,而是一个声明“不幸的是这是不可能的”。太可惜了:(
    猜你喜欢
    • 1970-01-01
    • 2020-03-05
    • 2023-03-26
    • 2011-12-20
    • 2020-09-26
    • 1970-01-01
    • 1970-01-01
    • 2015-12-17
    • 1970-01-01
    相关资源
    最近更新 更多