在 Delphi 中为 GetHashCode 将 Double 转换为 Integer

Question

Delphi 2009 将 GetHashCode 函数添加到 TObject。 GetHashCode 返回一个 Integer，用于 TDictionary 中的散列。

如果您希望一个对象在 TDictionary 中正常工作，您需要适当地覆盖 GetHashCode，这样通常不同的对象返回不同的整数哈希码。

但是对于包含双字段的对象，你会怎么做呢？如何将这些双精度值转换为 GetHashCode 的整数？

在 Java 中通常使用的方法是使用 Double.doubleToLongBits 或 Float.floatToIntBits 之类的方法。后者的文档描述如下：“根据 IEEE 754 浮点“单一格式”位布局返回指定浮点值的表示。”这涉及到对浮点值的不同位使用不同掩码的一些按位运算。

Delphi 中是否有这样的功能？

Answer 1

我建议对 Gamecat 代码进行以下改进：

type
  TVarRec = record
    case Integer of
      0: ( FInt1, FInt2 : Integer; )
      1: ( FDouble : Double; )
  end;

function Convert(const ADouble: Double): Integer;
var
  arec : TVarRec;
begin
  arec.FDouble := ADouble;
  Result := arec.FInt1 xor arec.FInt2;
end;

这会考虑到 Double 值的所有位。

（cmets 不适用于代码）

Answer 2

如果要将双精度数映射到整数，可以使用变体记录：

type
  TVarRec = record
    case Integer of
      0: ( FInt : Integer; )
      1: ( FDouble : Double; )
  end;


function Convert(const ADouble: Double): Integer;
var
  arec : TVarRec;
begin
  arec.FDouble := ADouble;
  Result := arec.FInt;
end;

请注意，这会在不解释值的情况下进行按位复制。

另一个（一种肮脏的技巧，是使用绝对变量：

function Convert(const ADouble: Double): Integer;
var
  tempDouble : Double;
  tempInt    : Integer absolute tempDouble; // tempInt is at the same memory position as tempDouble.
begin
  tempDouble := ADouble;
  Result := tempInt;
end;

Answer 3

真的没有必要做这样的事情，因为 GetHashCode 的默认值已经返回了一个保证每个对象都是唯一的数字：对象的内存地址。此外，如果您更改对象包含的数据，默认哈希值不会改变。

假设您有一个对象，其中包含一个值为 3.5 的 Double，您对其进行哈希处理并将其放入字典中，得到哈希码 12345678。您还有其他东西持有对它的引用，并且 Double 字段被更改，现在它的值为 5.21。下次您尝试计算其哈希值时，您的哈希码现在是 23456789，您的查找将失败。

除非您可以保证这永远不会发生，并且您有充分的理由不使用内存地址，否则最好的选择是保持 GetHashCode 不变。 （如果它没有坏，就不要修理它。）

Answer 4

我猜Java的东西可以像这样在Delphi中实现：

type
  TVarRec = record
    case Integer of
      0: ( FInt1: Integer; )
      1: ( FSingle: Single; )
  end;

function GetHashCode(Value: Double): Integer;
var
  arec: TVarRec;
begin
  arec.FSingle := Value;
  Result := arec.FInt1;
end;

背后的想法是降低 Double 值的精度以匹配 Integer 的二进制大小（Sizeof(Single) = Sizeof(Integer)）。如果您的值可以用单精度表示而不会发生冲突，那么这将提供一个很好的哈希值。

编辑：由于 typecast 在我的 D2009 中无法编译，我调整了变体记录解决方案。

Answer 5

对 Double 数据使用 CRC32，因为 xor 是邪恶的。

program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TVarRec = record
    case Integer of
      0: ( FInt1, FInt2 : Integer; );
      1: ( FDouble : Double; );
  end;

function Convert(const ADouble: Double): Integer;
var
  arec : TVarRec;
begin
  arec.FDouble := ADouble;
  Result := arec.FInt1 xor arec.FInt2;
end;

var
  FDoubleVar1, FDoubleVar2: TVarRec;
  HashCode1, HashCode2: Integer;
begin
  // Make a Double
  FDoubleVar1.FInt1 := $DEADC0DE;
  FDoubleVar1.FInt2 := $0C0DEF00;

  // Make another Double
  FDoubleVar2.FInt1 := $0C0DEF00;
  FDoubleVar2.FInt2 := $DEADC0DE;

  WriteLn('1rst Double   : ', FDoubleVar1.FDouble);
  WriteLn('2nd Double    : ', FDoubleVar2.FDouble);

  HashCode1 := Convert(FDoubleVar1.FDouble);
  HashCode2 := Convert(FDoubleVar2.FDouble);

  WriteLn('1rst HashCode : ', HashCode1);
  WriteLn('2nd HashCode  : ', HashCode2);

  if HashCode1 = HashCode2 then
  begin
    WriteLn('Warning: Same HashCode!');
  end;
  ReadLn;
end.