使用 unicode 字符属性时如何模拟单词边界？

Question

从我之前的问题Why under locale-pragma word characters do not match? 和How to change nested quotes 我了解到，在处理 UTF-8 数据时，您不能将 \w 视为 word-char，您必须使用 Unicode 字符属性 \p{Word}。现在我发现零宽度字边界\b 也不适用于 UTF-8（启用了语言环境），但我在 Unicode 字符属性中没有找到任何等效项。我想我可以自己构造它：(?<=\P{Word})(\p{Word}+)(?=\P{Word})，它应该相当于\b(\w+)\b。

在下面的测试脚本中，我有两个数组来测试两个不同的正则表达式。第一个基于\b 在未启用区域设置时工作正常。为了让它也适用于语言环境，我编写了另一个带有模拟边界(?=\P{Word}) 的版本，但它没有按我的预期工作（我也在脚本中显示了预期的结果）。

您知道什么是错误的吗？如何让模拟的正则表达式首先使用 ASCII（或没有语言环境）？

#!/usr/bin/perl

use 5.010;
use utf8::all;
use locale; # et_EE.UTF-8 in my case
$| = 1;

my @test_boundary = (  # EXPECTED RESULT:
  '"abc def"',         # '«abc def»'
  '"abc "d e f" ghi"', # '«abc «d e f» ghi»'
  '"abc "d e f""',     # '«abc «d e f»»'
  '"abc "d e f"',      # '«abc "d e f»'
  '"abc "d" "e" f"',   # '«abc «d» «e» f»'
  # below won't work with \b when locale enabled
  '"100 Естонiï"',     #  '«100 Естонiï»'
  '"äöõ "ä õ ü" ï"',   # '«äöõ «ä õ ü» ï»'
  '"äöõ "ä õ ü""',     # '«äöõ «ä õ ü»»'
  '"äöõ "ä õ ü"',      # '«äöõ «ä õ ü»'
  '"äöõ "ä" "õ" ï"',   # '«äöõ «ä» «õ» ï»'
);

my @test_emulate = (   # EXPECTED RESULT:
  '"100 Естонiï"',     # '«100 Естонiï»'
  '"äöõ "ä õ ü" ï"',   # '«äöõ «ä õ ü» ï»'
  '"äöõ "ä õ ü""',     # '«äöõ «ä õ ü»»'
  '"äöõ "ä õ ü"',      # '«äöõ "ä õ ü»'
  '"äöõ "ä" "õ" ï"',   # '«äöõ «ä» «õ» ï»'
);

say "BOUNDARY";
for my $sentence ( @test_boundary ) {
  my $quote_count = ( $sentence =~ tr/"/"/ );

  for ( my $i = 0 ; $i <= $quote_count ; $i += 2 ) {
    $sentence =~ s/
      "(                          # first qoute, start capture
        [\p{Word}\.]+?            # suva word-char
        .*?\b[\.,?!»]*?           # any char followed boundary + opt. punctuation
      )"                          # stop capture, ending quote
      /«$1»/xg;                   # change to fancy
  }
  say $sentence;
}

say "EMULATE";
for my $sentence ( @test_emulate ) {
  my $quote_count =  ( $sentence =~ tr/"/"/ );

  for ( my $i = 0 ; $i <= $quote_count ; $i += 2 ) {
    $sentence =~ s/
      "(                         # first qoute, start capture
      [\p{Word}\.]+?             # at least one word-char or point
      .*?(?=\P{Word})            # any char followed boundary 
      [\.,?!»]*?                 # optional punctuation
      )"                         # stop capture, ending quote
      /«$1»/gx;                  # change to fancy
  }
  say $sentence;
}

Answer 1

您应该使用负面的环视：

(?<!\p{Word})(\p{Word}+)(?!\p{Word})

正向环视在字符串的开头或结尾失败，因为它们需要一个非单词字符。否定的环视方法在这两种情况下都有效。

Answer 2

由于\b后面的字符要么是一些标点符号要么是"（为安全起见，请仔细检查\p{Word}与它们中的任何一个都不匹配），它属于\b\W的情况.因此，我们可以模拟\b：

(?<=\p{Word})

我不熟悉 Perl，但从 what I tested here 看来，\w（和 \b）在编码设置为 UTF-8 时也能很好地工作。

$sentence =~ s/
  "(
    [\w\.]+?
    .*?\b[\.,?!»]*?
  )"
  /«$1»/xg;

如果您升级到 Perl 5.14 及更高版本，您可以使用 u 标志将字符集设置为 Unicode。

---

您可以使用这种通用策略来构造与字符类对应的边界。 （就像\b字边界的定义是基于\w的定义一样）。

让C 成为字符类。我们想定义一个基于字符类 C 的边界。

当你知道当前字符属于C字符类（相当于(\b\w)）时，下面的构造将模拟前面的边界：

(?<!C)C

或者后面（相当于\w\b）：

C(?!C)

为什么要负环视？因为正环环视（使用互补字符类）也会断言前面/后面必须有一个字符（断言 width至少在前面/后面 1)。负环视将允许字符串的开始/结束的情况，而无需编写繁琐的正则表达式。

---

对于\B\w 仿真：

(?<=C)C

同样\w\B:

C(?=C)

\B 与\b 正好相反，因此，我们可以翻转正/负环视来模拟效果。这也是有道理的——只有在前面/后面有更多字符时才能形成无边界。

---

其他仿真（设c 为C 的补码字符类）：

• \b\W: (?<=C)c
• \W\b: c(?=C)
• \B\W: (?<!C)c
• \W\B: c(?!C)

---

对于独立边界的模拟（相当于\b）：

(?:(?<!C)(?=C)|(?<=C)(?!C))

和独立无边界（相当于\B）：

(?:(?<!C)(?!C)|(?<=C)(?=C))