将 Mathematica 值列表转换为布尔列表

Question

首先，很抱歉标题混乱。

我想做的是将{1, 4, 9}转换为：

{True, False, False, True, False, False, False, False, True}

也就是说，只有第一个列表中的索引的值为True，其余的为False。

我感觉有一些非常简单的解决方案，但我对 Mathematica 和函数式编程都很陌生。我可以在一个循环中迭代地完成它，但必须有一些东西可以与整个列表一起使用。正确的？ :)

感谢您的帮助。

---

编辑：表明我在问之前尝试做某事，这是我到目前为止的进展：

first={1,4,9}
ReplacePart[Table[False, {x, Max[first]}], {1} -> True]
(* gives {True, False, False, False, False, False, False, False, False} *)

不幸的是，它不适用于{1,4,9} -> True，但可以用于{1 -> True, 4 -> True, 9 -> True}。但我不知道该怎么做......

---

编辑 2： 明白了。

ReplacePart[Table[False, {x, Max[first]}], Table[x -> True, {x, first}]]

我仍然希望看到您的解决方案！这对我来说似乎是一个丑陋的黑客...... :)

Answer 1

我将使用SparseArray 进行此操作。在我看来，它很容易理解，而且效率也很高，尤其是在低百分比的索引为 True 时。

true = {1, 4, 9};
SparseArray[(List /@ true) -> True, Automatic, False]

或者使用Transpose（粘贴到Mathematica时看起来更好）：

SparseArray[{true}\[Transpose] -> True, Automatic, False]

如果您必须将输出转换为普通数组，您可以使用Normal，但大多数操作不需要。

---

另外，为了简洁而牺牲实用性：

#==1 & /@ SparseArray[List /@ true -> 1]

Answer 2

这是一个简单的方法：

first = {1, 4, 9};
list = ConstantArray[False, Max@first];
list[[first]] = True;

list
Out[1]= {True, False, False, True, False, False, False, False, True}

---

这是上面写成一个方便函数的解决方案：

Clear[convertIndices]
convertIndices[index_List] := 
 Module[{list = ConstantArray[False, Max@index]}, 
  list[[index]] = True; list]

用法：

convertIndices@{1, 4, 9}
Out[2]= {True, False, False, True, False, False, False, False, True}

Answer 3

实际上，我自己会使用尤达的答案，但这里有一个替代方案：

first = {1, 4, 9};
MemberQ[first, #] & /@ Range[Max[first]]

(* ===> {True, False, False, True, False, False, False, False, True}*)

或者这个：

Or @@@ Outer[Equal, Range[Max[first]], first]


(* ===> {True, False, False, True, False, False, False, False, True}*)

两者都有跳过 Yoda 的 ConstantArray 初始化步骤的优势。