TSQL - 如何在 BEGIN .. END 块中使用 GO？

Question

我正在生成一个脚本，用于将更改从多个开发数据库自动迁移到登台/生产。基本上，它需要一堆更改脚本，并将它们合并为一个脚本，将每个脚本包装在 IF whatever BEGIN ... END 语句中。

但是，有些脚本需要 GO 语句，以便 SQL 解析器在创建新列后知道它。

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

但是，一旦我将其包装在 IF 块中：

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

它失败了，因为我发送的 BEGIN 没有匹配的 END。但是，如果我删除 GO 它会再次抱怨未知列。

有没有办法在单个 IF 块中创建和更新同一列？

Answer 1

我遇到了同样的问题，最后设法使用 SET NOEXEC 解决了它。

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

Answer 2

GO 不是 SQL - 它只是一些 MS SQL 工具中使用的批处理分隔符。

如果你不使用它，你需要确保语句是分开执行的——无论是在不同的批次中，还是通过对人口使用动态 SQL（感谢@gbn）：

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Answer 3

您可以尝试sp_executesql，将每个GO 语句之间的内容拆分为单独的字符串以执行，如下例所示。此外，还有一个 @statementNo 变量来跟踪正在执行的语句，以便于调试发生异常的位置。行号将相对于导致错误的相关语句号的开头。

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

您还可以轻松地执行多行语句，如上例所示，只需将它们括在单引号中 (')。生成脚本时，不要忘记使用双单引号 ('') 转义字符串中包含的任何单引号。

Answer 4

您可以将语句括在 BEGIN 和 END 中，而不是中间的 GO

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

（在 Northwind 数据库上测试）

编辑：（可能在 SQL2012 上测试过）

Answer 5

我最终通过将 GO 的每个实例替换为自己的行来使其工作

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

这比将每组语句包装在一个字符串中要好得多，但仍然远理想。如果有人找到更好的解决方案，请发布它，我会接受它。

Answer 6

你可以试试这个解决方案：

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

Answer 7

我过去曾为此使用过RAISERROR

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Answer 8

您可以合并GOTO 和LABEL 语句来跳过代码，从而保持GO 关键字不变。