为什么我的序言规则陷入无限递归

Question

我的代码可以达到预期目的，但最后总是卡在一个循环中，给我一个错误，提示“超出堆栈限制”。我的代码如下：

byCar(auckland,hamilton).
byCar(hamilton,raglan).
byCar(valmont,saarbruecken).
byCar(valmont,metz).
   
byTrain(metz,frankfurt).
byTrain(saarbruecken,frankfurt).
byTrain(metz,paris).
byTrain(saarbruecken,paris).
   
byPlane(frankfurt,bangkok).
byPlane(frankfurt,singapore).
byPlane(paris,losAngeles).
byPlane(bangkok,auckland).
byPlane(singapore,auckland).
byPlane(losAngeles,auckland).


travel(X,Y):- byCar(X,Y).
travel(X,Y):- byTrain(X,Y).
travel(X,Y):- byPlane(X,Y).
travel(X,Y):- travel(X,Z), travel(Z,Y).

Answer 1

当你调用travel(metz, To)之类的东西时，travel/2 的最后一个子句将调用 travel(metz, Z) 并带有一个新变量 Z，然后它可以调用 travel(metz, Z2) 并带有一个新变量 Z2，依此类推.

这个问题被称为“左递归”：你有一个递归调用，它等效于原始目标一直到子句的“左侧”（即开头）。解决方案是在递归调用之前“取得一些进展”。在这种情况下，您可以在递归之前移动一跳：

step(X, Y) :-
    byCar(X, Y).
step(X, Y) :-
    byTrain(X, Y).
step(X, Y) :-
    byPlane(X, Y).

travel(X, Y) :-
    step(X, Y).
travel(X, Z) :-
    step(X, Y),
    travel(Y, Z).

现在结束：

?- travel(metz, To).
To = frankfurt ;
To = paris ;
To = bangkok ;
To = singapore ;
To = auckland ;
To = hamilton ;
To = raglan ;
To = auckland ;
To = hamilton ;
To = raglan ;
To = losAngeles ;
To = auckland ;
To = hamilton ;
To = raglan ;
false.

正如false 的评论中所指出的，您可以使用通用谓词来捕获这种闭包：Definition of Reflexive Transitive Closure。或者，一些 Prolog 系统提供了一种称为“表格”的功能，您可以使用它来避免此类问题：https://www.swi-prolog.org/pldoc/man?section=tabling-non-termination