【问题标题】:How to increase performance for bulk INSERTs to ODBC linked tables in Access for multiple columns?如何在 Access 中为多列提高批量插入到 ODBC 链接表的性能?
【发布时间】:2015-12-21 23:24:56
【问题描述】:

本题基于此题:How to increase performance for bulk INSERTs to ODBC linked tables in Access?

我对上面的链接主题有进一步的问题,因为我没有足够的分数来评论这个主题,所以我在这里创建了我的问题。

Gord Thompson 给出了出色的回答,他在上面的链接中提供了以下代码。

Sub PtqTest()
Dim cdb As DAO.Database, rst As DAO.Recordset
Dim t0 As Single, i As Long, valueList As String, separator As String

t0 = Timer
Set cdb = CurrentDb
Set rst = cdb.OpenRecordset("SELECT MPO_REFERENCE FROM tblTempSmartSSP", dbOpenSnapshot)
i = 0
valueList = ""
separator = ""
Do Until rst.EOF
    i = i + 1
    valueList = valueList & separator & "(" & rst!MPO_REFERENCE & ")"
    If i = 1 Then
        separator = ","
    End If
    If i = 1000 Then
        SendInsert valueList
        i = 0
        valueList = ""
        separator = ""
    End If
    rst.MoveNext
Loop
If i > 0 Then
    SendInsert valueList
End If
rst.Close
Set rst = Nothing
Set cdb = Nothing
Debug.Print "Elapsed time " & Format(Timer - t0, "0.0") & " seconds."
End Sub

Sub SendInsert(valueList As String)
Dim cdb As DAO.Database, qdf As DAO.QueryDef

Set cdb = CurrentDb
Set qdf = cdb.CreateQueryDef("")
qdf.Connect = cdb.TableDefs("METER_DATA").Connect
qdf.ReturnsRecords = False
qdf.sql = "INSERT INTO METER_DATA (MPO_REFERENCE) VALUES " & valueList
qdf.Execute dbFailOnError
Set qdf = Nothing
Set cdb = Nothing
End Sub

我的问题是如果我想在插入过程中包含多个列怎么办?例如,除了 MPO_REFERENCE,我还有其他名为 NEW_COLUMN 的列想要插入到 METER_DATA (来自 sql server 的 odbc 链接表),我尝试对上述代码中的某些行进行以下修改,但失败了。抱歉,我是 SQL 和 VB 的新手,如果有人可以提供帮助,将不胜感激。谢谢。

    ...
    Set rst = cdb.OpenRecordset("SELECT MPO_REFERENCE,NEW_COLUMN FROM tblTempSmartSSP", dbOpenSnapshot)
    ...
    ...
        valueList = valueList & separator & "(" & rst!MPO_REFERENCE & "," & rst!NEW_COLUMN & ")"

    ...
    ...
    qdf.sql = "INSERT INTO METER_DATA (MPO_REFERENCE,NEW_COLUMN) VALUES " & valueList

    ...

【问题讨论】:

  • 请更改您的标题。它具有误导性,因为它与您的最后一个问题无关。您可以解释一下,您在问题文本中找到了代码。

标签: sql-server tsql ms-access odbc ms-access-2010


【解决方案1】:

基本上,你明白了,代码是正确的。

但是还有一些其他的事情你必须考虑:

  1. 如果rst!NEW_COLUMN 为空,则将空字符串传递给 SQL 命令,这将导致错误。

    例如导致 SQL 字符串的错误:

    INSERT INTO METER_DATA (MPO_REFERENCE,NEW_COLUMN) VALUES (3, )

    在构建 SQL 字符串之前检查 NEW_COLUMN 是否为空

  2. 如果 NEW_COLUMN 是字符串值,则必须在单引号之间设置。这看起来像这样:

    valueList = valueList & separator & "(" & rst!MPO_REFERENCE _ & ",'" & rst!NEW_COLUMN & "')"

第二个考虑可能也解决了第一个考虑,因为它将...VALUES (3, )... 更改为提供空字符串插入的...VALUES (3, '')...。

我假设,MPO_REFERENCE 不带单引号,因为它是一个数字。

【讨论】:

    猜你喜欢
    • 2021-07-11
    • 2018-11-02
    • 1970-01-01
    • 2013-07-23
    • 2016-01-05
    • 2019-12-07
    • 1970-01-01
    • 1970-01-01
    相关资源
    最近更新 更多