从 VBA 数组中删除反向重复项

Question

我需要从数组中删除反向重复。

从1,2 和2,1 我想删除2,1，因为它的反向是1,2 的重复。

Sub go()
    Dim arr() As String
    ReDim Preserve arr(0)

    Dim i, k As Integer

    For i = 1 To 2
        For k = 1 To 10    
            If i <> k Then
                arr(UBound(arr)) = i & "," & k
                ReDim Preserve arr(UBound(arr) + 1)
            End If
        Next
    Next
    'Debug.Print Join(arr, vbCrLf)

    For z = 0 To UBound(arr)
        For q = 0 To UBound(arr)    
            rev = StrReverse(arr(z))
            If arr(q) = rev Then
                Debug.Print arr(z) & "-" & rev
            End If
        Next
    Next
End Sub

Answer 1

正如 cmets 所说，最简单的方法是创建一个新数组并向其中添加元素。同样正如 Hel O'Ween 所说，VBA 变量需要像下面这样的显式声明。

Public Sub goTest()

Dim inputArray() As String
ReDim Preserve inputArray(0)
Dim resultArray() As String
ReDim Preserve resultArray(0)

Dim i As Long, j As Long
Dim rev As String, notDuped As Boolean

'[[-- Loop to generate the test array
For i = 1 To 2
    For j = 1 To 10
        If i <> j Then
            inputArray(UBound(inputArray)) = i & "," & j
            ReDim Preserve inputArray(UBound(inputArray) + 1)
        End If
    Next j
Next i
'--]]

'The actual reverse removed code
For i = 0 To UBound(inputArray)
    rev = StrReverse(inputArray(i))
    notDuped = True
    For j = 0 To i 'Only loop up to the current point, not all of the array
        If inputArray(j) = rev Then
            notDuped = False
            Exit For
        End If
    Next j
    If notDuped Then 'If no reverse found add to new array
        resultArray(UBound(resultArray)) = inputArray(i)
        ReDim Preserve resultArray(UBound(resultArray) + 1)
    End If
Next i

'[[-- To check that it worked
For i = 0 To UBound(resultArray)
    Debug.Print (resultArray(i))
Next i
'--]]

End Sub

代码的底部仅输出结果数组，因此您可以看到它没有反转，它与代码正常工作无关。

如果您对此有任何问题，请给我留言，我会尽快回复您。