可以在 VBScript 中按名称访问 WMI 对象的属性吗？答案

【问题标题】：Possible to access a WMI object's properties BY NAME in VBScript?可以在 VBScript 中按名称访问 WMI 对象的属性吗？
【发布时间】：2011-05-14 05:43:21
【问题描述】：

而不是这样的代码：

On Error Resume Next
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_IP4RouteTable",,48)
For Each objItem in colItems
    Wscript.Echo "Age: " & objItem.Age
    Wscript.Echo "Caption: " & objItem.Caption
    Wscript.Echo "Description: " & objItem.Description
Next

是否可以按名称访问每个属性，类似于以下语法之一：

Wscript.Echo "Age: " & objItem("Age")
Wscript.Echo "Age: " & objItem.Properties("Age")
Wscript.Echo "Age: " & objItem.Item("Age")

甚至更好的是，有什么方法可以做到：

Dim colItems
Dim objItem
Dim aProperty
Set colItems = objWMIService.ExecQuery("Select * from Win32_IP4RouteTable",,48)
For Each objItem in colItems
   For Each aProperty in objItem.Properties
       Wscript.Echo aProperty.Name & ": " & objItem(aProperty.Name)
   Next
Next

【问题讨论】：

标签： com vbscript wmi

【解决方案1】：

您可以通过Properties_ 属性访问 WMI 对象的命名属性：

objItem.Properties_("Age")
objItem.Properties_.Item("Age")

当然，你也可以枚举Properties_集合：

For Each objItem in colItems
  For Each prop in objItem.Properties_
    If IsArray(prop) Then
      WScript.Echo prop.Name & ": " & Join(prop, ", ")
    Else
      Wscript.Echo prop.Name & ": " & prop
      ''# -- or --
      ''# Wscript.Echo prop.Name & ": " & prop.Value
    End If
  Next
Next

【讨论】：