使用 VB6 将属性写入 XML 中的子节点答案

【问题标题】：Writing Attributes to a subnode in XML with VB6使用 VB6 将属性写入 XML 中的子节点
【发布时间】：2014-12-04 20:04:12
【问题描述】：

我在 VB6 中使用“DOMDocument60”，我需要生成一个 XML 文件，但在尝试将“属性”添加到子节点时遇到问题。这是生成我的代码的文件：

<myroot>
<MyNode SIZE="10">
<SubNode/>
</MyNode>
</myroot>

这就是我需要的：

<myroot>
<MyNode SIZE="10">
**<SubNode CODE="0000" ID="XXX" OTHER="XXX"/>**
</MyNode>
</myroot>

这是代码（基于http://msdn.microsoft.com/en-us/library/ms760231%28v=vs.85%29.aspx）：

私有函数 CrearDOM() 昏暗的域设置 dom = New DOMDocument60 dom.async = 假 dom.validateOnParse = False dom.resolveExternals = False dom.preserveWhiteSpace = True 设置 CrearDOM = dom 结束函数

公共订阅 Crear_XML()

Set dom = CrearDOM

' Encabezado de XML
Set node = dom.createProcessingInstruction("xml", "version='1.0' encoding='iso-8859-1'")
dom.appendChild node
Set node = Nothing

    Dim MyRoot
    Set MyRoot = dom.createElement("MasRequest")
MyRoot.appendChild dom.createTextNode(vbNewLine + vbTab)

    Set node = dom.createElement("MyNode")
    Set attr = dom.createAttribute("SIZE") 
    attr.Value = 10
    node.setAttributeNode attr
    Set attr = Nothing

        Set Nodo_Sub = dom.createDocumentFragment
        Nodo_Sub.appendChild dom.createTextNode(vbNewLine + vbTab + vbTab)
        Nodo_Sub.appendChild dom.createElement("SubNode")

    node.appendChild Nodo_Droga

MyRoot.appendChild node
End Sub

感谢您的帮助。

【问题讨论】：

请出示您已有的代码以便更正。
对不起，我是论坛的新手，所以最好重新编辑原帖

标签： xml vb6

【解决方案1】：

您的问题是您在创建子节点后没有向子节点添加任何属性。我根据您的代码编写了一个示例，但我更改了一些只是因为我习惯这样做。

Private Function CrearDOM()
    Dim dom As DOMDocument60

    Set dom = New DOMDocument60
    With dom
        .async = False 
        .validateOnParse = False
        .resolveExternals = False
        .preserveWhiteSpace = True
    End With
    Set CrearDOM = dom
End Function

Public Sub Crear_XML()
    Dim dom As DOMDocument60
    Dim MyRoot As IXMLDOMNode
    Dim node
    Dim childNode As IXMLDOMNode
    Dim attr

    Set dom = New DOMDocument60
    With dom
        .async = False
        .validateOnParse = False
        .resolveExternals = False
        .preserveWhiteSpace = True
    End With

    Set node = dom.createProcessingInstruction("xml", "version='1.0' encoding='iso-8859-1'")
    dom.appendChild node
    Set node = Nothing

    Set MyRoot = dom.createElement("MasRequest")
    MyRoot.appendChild dom.createTextNode(vbNewLine + vbTab)

    Set node = dom.createElement("MyNode")
    Set attr = dom.createAttribute("SIZE")
    attr.Value = 10
    node.setAttributeNode attr
    Set attr = Nothing

    'create the child node'
    Set childNode = dom.createElement("SubNode")
    Set attr = dom.createAttribute("CODE")
    attr.Value = "0000"
    childNode.Attributes.setNamedItem attr
    Set attr = dom.createAttribute("ID")
    attr.Value = "XXX"
    childNode.Attributes.setNamedItem attr
    Set attr = dom.createAttribute("OTHER")
    attr.Value = "XXX"
    childNode.Attributes.setNamedItem attr
    node.appendChild childNode
    MyRoot.appendChild node
    dom.appendChild MyRoot

End Sub

上面的代码为我生成了这个。（我添加了换行符和缩进。）

<?xml version="1.0"?>
<MasRequest>
    <MyNode SIZE="10">
        <SubNode CODE="0000" ID="XXX" OTHER="XXX"/>
    </MyNode>
</MasRequest>

【讨论】：